ਸਮੱਗਰੀ
ਇਹ ਛੋਟਾ ਟਿਊਟੋਰਿਅਲ ਦੱਸਦਾ ਹੈ ਕਿ ਫੰਕਸ਼ਨ ਕਿਵੇਂ ਬਣਾਇਆ ਜਾਵੇ ਵੀਪੀਆਰ (VLOOKUP) ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ, ਕਈ ਹੋਰ ਫਾਰਮੂਲੇ ਦਿਖਾਉਂਦਾ ਹੈ ਜੋ ਐਕਸਲ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਤਰੀਕੇ ਨਾਲ ਖੋਜ ਕਰ ਸਕਦਾ ਹੈ, ਅਤੇ ਹਰੇਕ ਫੰਕਸ਼ਨ ਦੀਆਂ ਸ਼ਕਤੀਆਂ ਅਤੇ ਕਮਜ਼ੋਰੀਆਂ ਨੂੰ ਦਰਸਾਉਂਦਾ ਹੈ।
ਮੇਰਾ ਅੰਦਾਜ਼ਾ ਹੈ ਕਿ ਹਰੇਕ ਐਕਸਲ ਉਪਭੋਗਤਾ ਜਾਣਦਾ ਹੈ ਕਿ ਕਿਹੜਾ ਫੰਕਸ਼ਨ ਲੰਬਕਾਰੀ ਖੋਜ ਕਰਦਾ ਹੈ। ਇਹ ਸਹੀ ਹੈ, ਇਹ ਇੱਕ ਫੰਕਸ਼ਨ ਹੈ ਵੀਪੀਆਰ. ਹਾਲਾਂਕਿ, ਬਹੁਤ ਘੱਟ ਲੋਕ ਇਹ ਜਾਣਦੇ ਹਨ ਵੀਪੀਆਰ ਅੱਖਰ ਸੰਵੇਦਨਸ਼ੀਲ ਨਹੀਂ ਹੈ, ਭਾਵ ਇਸਦੇ ਲਈ ਛੋਟੇ ਅਤੇ ਵੱਡੇ ਅੱਖਰ ਇੱਕੋ ਜਿਹੇ ਹਨ।
ਇੱਥੇ ਅਸਮਰੱਥਾ ਦਾ ਪ੍ਰਦਰਸ਼ਨ ਕਰਨ ਵਾਲੀ ਇੱਕ ਤੇਜ਼ ਉਦਾਹਰਣ ਹੈ ਵੀਪੀਆਰ ਪਛਾਣ ਰਜਿਸਟਰ. ਮੰਨ ਲਓ ਕਿ ਇੱਕ ਸੈੱਲ ਵਿੱਚ A1 ਮੁੱਲ "ਬਿੱਲ" ਅਤੇ ਸੈੱਲ ਰੱਖਦਾ ਹੈ A2 - "ਬਿੱਲ", ਫਾਰਮੂਲਾ:
=VLOOKUP("Bill",A1:A10,2)
=ВПР("Bill";A1:A10;2)
… "ਬਿੱਲ" 'ਤੇ ਇਸਦੀ ਖੋਜ ਨੂੰ ਰੋਕ ਦੇਵੇਗਾ ਕਿਉਂਕਿ ਉਹ ਮੁੱਲ ਸੂਚੀ ਵਿੱਚ ਪਹਿਲਾਂ ਆਉਂਦਾ ਹੈ, ਅਤੇ ਸੈੱਲ ਤੋਂ ਮੁੱਲ ਨੂੰ ਐਕਸਟਰੈਕਟ ਕਰਦਾ ਹੈ B1.
ਬਾਅਦ ਵਿੱਚ ਇਸ ਲੇਖ ਵਿੱਚ, ਮੈਂ ਤੁਹਾਨੂੰ ਦਿਖਾਵਾਂਗਾ ਕਿ ਕਿਵੇਂ ਕਰਨਾ ਹੈ ਵੀਪੀਆਰ ਕੇਸ ਸੰਵੇਦਨਸ਼ੀਲ. ਇਸ ਤੋਂ ਇਲਾਵਾ, ਅਸੀਂ ਕੁਝ ਹੋਰ ਫੰਕਸ਼ਨ ਸਿੱਖਾਂਗੇ ਜੋ ਐਕਸਲ ਵਿੱਚ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਖੋਜਾਂ ਕਰ ਸਕਦੇ ਹਨ।
ਅਸੀਂ ਸਭ ਤੋਂ ਸਰਲ ਨਾਲ ਸ਼ੁਰੂ ਕਰਾਂਗੇ - VIEW ਦੇਖੋ (LOOKUP) ਅਤੇ SUMPRODUCT (SUMPRODUCT), ਜਿਸ ਵਿੱਚ ਬਦਕਿਸਮਤੀ ਨਾਲ, ਕਈ ਮਹੱਤਵਪੂਰਨ ਸੀਮਾਵਾਂ ਹਨ। ਅੱਗੇ, ਅਸੀਂ ਥੋੜ੍ਹਾ ਹੋਰ ਗੁੰਝਲਦਾਰ ਫਾਰਮੂਲੇ 'ਤੇ ਡੂੰਘਾਈ ਨਾਲ ਵਿਚਾਰ ਕਰਾਂਗੇ INDEX+MATCH (INDEX+MATCH), ਜੋ ਕਿ ਕਿਸੇ ਵੀ ਸਥਿਤੀ ਵਿੱਚ ਅਤੇ ਕਿਸੇ ਵੀ ਡੈਟਾਸੈੱਟ ਦੇ ਨਾਲ ਨਿਰਵਿਘਨ ਕੰਮ ਕਰਦਾ ਹੈ।
VLOOKUP ਫੰਕਸ਼ਨ ਕੇਸ ਸੰਵੇਦਨਸ਼ੀਲ ਹੈ
ਜਿਵੇਂ ਕਿ ਤੁਸੀਂ ਪਹਿਲਾਂ ਹੀ ਜਾਣਦੇ ਹੋ, ਆਮ ਫੰਕਸ਼ਨ ਵੀਪੀਆਰ ਕੇਸ ਅਸੰਵੇਦਨਸ਼ੀਲ ਹੈ। ਹਾਲਾਂਕਿ, ਇਸ ਨੂੰ ਕੇਸ ਸੰਵੇਦਨਸ਼ੀਲ ਬਣਾਉਣ ਦਾ ਇੱਕ ਤਰੀਕਾ ਹੈ। ਅਜਿਹਾ ਕਰਨ ਲਈ, ਤੁਹਾਨੂੰ ਸਾਰਣੀ ਵਿੱਚ ਇੱਕ ਸਹਾਇਕ ਕਾਲਮ ਜੋੜਨ ਦੀ ਲੋੜ ਹੈ, ਜਿਵੇਂ ਕਿ ਹੇਠਾਂ ਦਿੱਤੀ ਉਦਾਹਰਣ ਵਿੱਚ ਦਿਖਾਇਆ ਗਿਆ ਹੈ।
ਇੱਕ ਕਾਲਮ ਵਿੱਚ ਮੰਨ ਲਓ B ਉਤਪਾਦ ਪਛਾਣਕਰਤਾ (ਆਈਟਮ) ਹਨ ਅਤੇ ਤੁਸੀਂ ਕਾਲਮਾਂ ਤੋਂ ਉਤਪਾਦ ਦੀ ਕੀਮਤ ਅਤੇ ਸੰਬੰਧਿਤ ਟਿੱਪਣੀ ਨੂੰ ਕੱਢਣਾ ਚਾਹੁੰਦੇ ਹੋ C и D. ਸਮੱਸਿਆ ਇਹ ਹੈ ਕਿ ਪਛਾਣਕਰਤਾਵਾਂ ਵਿੱਚ ਛੋਟੇ ਅਤੇ ਵੱਡੇ ਅੱਖਰ ਦੋਵੇਂ ਹੁੰਦੇ ਹਨ। ਉਦਾਹਰਨ ਲਈ, ਸੈੱਲ ਮੁੱਲ B4 (001Tvci3u) ਅਤੇ B5 (001Tvci3U) ਸਿਰਫ ਆਖਰੀ ਅੱਖਰ ਦੇ ਮਾਮਲੇ ਵਿੱਚ ਵੱਖਰਾ ਹੈ, u и U ਕ੍ਰਮਵਾਰ.
ਜਿਵੇਂ ਕਿ ਤੁਸੀਂ ਕਲਪਨਾ ਕਰ ਸਕਦੇ ਹੋ, ਆਮ ਖੋਜ ਫਾਰਮੂਲਾ
=VLOOKUP("001Tvci3U",$A$2:$C$7,2,FALSE)
=ВПР("001Tvci3U";$A$2:$C$7;2;ЛОЖЬ)
ਵਾਪਸ ਆਵੇਗਾ $90, ਮੁੱਲ ਤੋਂ 001Tvci3u ਇਸ ਤੋਂ ਪਹਿਲਾਂ ਖੋਜ ਰੇਂਜ ਵਿੱਚ ਹੈ 001Tvci3U. ਪਰ ਇਹ ਉਹ ਨਹੀਂ ਹੈ ਜਿਸਦੀ ਸਾਨੂੰ ਲੋੜ ਹੈ, ਕੀ ਇਹ ਹੈ?
ਇੱਕ ਫੰਕਸ਼ਨ ਨਾਲ ਖੋਜ ਕਰਨ ਲਈ ਵੀਪੀਆਰ ਐਕਸਲ ਕੇਸ ਸੰਵੇਦਨਸ਼ੀਲ ਵਿੱਚ, ਤੁਹਾਨੂੰ ਇੱਕ ਸਹਾਇਕ ਕਾਲਮ ਜੋੜਨਾ ਹੋਵੇਗਾ ਅਤੇ ਇਸ ਦੇ ਸੈੱਲਾਂ ਨੂੰ ਹੇਠਾਂ ਦਿੱਤੇ ਫਾਰਮੂਲੇ ਨਾਲ ਭਰਨਾ ਹੋਵੇਗਾ (ਜਿੱਥੇ B ਲੁਕਅੱਪ ਕਾਲਮ ਹੈ):
=CODE(MID(B2,1,1)) & CODE(MID(B2,2,1)) & CODE(MID(B2,3,1)) & CODE(MID(B2,4,1)) & CODE(MID(B2,5,1)) & CODE(MID(B2,6,1)) & CODE(MID(B2,7,1)) & CODE(MID(B2,8,1)) & IFERROR(CODE(MID(B2,9,1)),"")
=КОДСИМВ(ПСТР(B2;1;1)) & КОДСИМВ(ПСТР(B2;2;1)) & КОДСИМВ(ПСТР(B2;3;1)) & КОДСИМВ(ПСТР(B2;4;1)) & КОДСИМВ(ПСТР(B2;5;1)) & КОДСИМВ(ПСТР(B2;6;1)) & КОДСИМВ(ПСТР(B2;7;1)) & КОДСИМВ(ПСТР(B2;8;1)) & ЕСЛИОШИБКА(КОДСИМВ(ПСТР(B2;9;1));"")
ਇਹ ਫਾਰਮੂਲਾ ਲੋੜੀਂਦੇ ਮੁੱਲ ਨੂੰ ਵੱਖਰੇ ਅੱਖਰਾਂ ਵਿੱਚ ਵੰਡਦਾ ਹੈ, ਹਰੇਕ ਅੱਖਰ ਨੂੰ ਇਸਦੇ ਕੋਡ ਨਾਲ ਬਦਲਦਾ ਹੈ (ਉਦਾਹਰਨ ਲਈ, ਦੀ ਬਜਾਏ A 65 'ਤੇ, ਇਸ ਦੀ ਬਜਾਏ a ਕੋਡ 97) ਅਤੇ ਫਿਰ ਇਹਨਾਂ ਕੋਡਾਂ ਨੂੰ ਸੰਖਿਆਵਾਂ ਦੀ ਇੱਕ ਵਿਲੱਖਣ ਸਤਰ ਵਿੱਚ ਜੋੜਦਾ ਹੈ।
ਉਸ ਤੋਂ ਬਾਅਦ, ਅਸੀਂ ਇੱਕ ਸਧਾਰਨ ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰਦੇ ਹਾਂ ਵੀਪੀਆਰ ਕੇਸ ਸੰਵੇਦਨਸ਼ੀਲ ਖੋਜ ਲਈ:
=VLOOKUP($G$3,$A$2:$C$8,3,FALSE)
=ВПР($G$3;$A$2:$C$8;3;ЛОЖЬ)
ਫੰਕਸ਼ਨ ਦੀ ਸਹੀ ਕਾਰਵਾਈ ਵੀਪੀਆਰ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਦੋ ਕਾਰਕਾਂ 'ਤੇ ਨਿਰਭਰ ਕਰਦਾ ਹੈ:
- ਸਹਾਇਕ ਕਾਲਮ ਦੇਖਣਯੋਗ ਰੇਂਜ ਵਿੱਚ ਸਭ ਤੋਂ ਖੱਬਾ ਕਾਲਮ ਹੋਣਾ ਚਾਹੀਦਾ ਹੈ।
- ਜੋ ਮੁੱਲ ਤੁਸੀਂ ਲੱਭ ਰਹੇ ਹੋ ਉਸ ਵਿੱਚ ਅਸਲ ਮੁੱਲ ਦੀ ਬਜਾਏ ਇੱਕ ਅੱਖਰ ਕੋਡ ਹੋਣਾ ਚਾਹੀਦਾ ਹੈ।
CODE ਫੰਕਸ਼ਨ ਦੀ ਸਹੀ ਵਰਤੋਂ ਕਿਵੇਂ ਕਰੀਏ
ਸਹਾਇਕ ਕਾਲਮ ਦੇ ਸੈੱਲਾਂ ਵਿੱਚ ਸੰਮਿਲਿਤ ਫਾਰਮੂਲਾ ਇਹ ਮੰਨਦਾ ਹੈ ਕਿ ਤੁਹਾਡੇ ਸਾਰੇ ਖੋਜ ਮੁੱਲਾਂ ਵਿੱਚ ਇੱਕੋ ਜਿਹੇ ਅੱਖਰ ਹਨ। ਜੇਕਰ ਨਹੀਂ, ਤਾਂ ਤੁਹਾਨੂੰ ਸਭ ਤੋਂ ਛੋਟੇ ਅਤੇ ਵੱਡੇ ਨੰਬਰਾਂ ਨੂੰ ਜਾਣਨ ਦੀ ਲੋੜ ਹੈ ਅਤੇ ਵੱਧ ਤੋਂ ਵੱਧ ਵਿਸ਼ੇਸ਼ਤਾਵਾਂ ਜੋੜਨ ਦੀ ਲੋੜ ਹੈ IFERROR (IFERROR) ਸਭ ਤੋਂ ਛੋਟੇ ਅਤੇ ਸਭ ਤੋਂ ਲੰਬੇ ਖੋਜੇ ਗਏ ਮੁੱਲ ਵਿੱਚ ਕਿੰਨੇ ਅੱਖਰਾਂ ਦਾ ਅੰਤਰ ਹੈ।
ਉਦਾਹਰਨ ਲਈ, ਜੇਕਰ ਸਭ ਤੋਂ ਛੋਟਾ ਖੋਜ ਮੁੱਲ 3 ਅੱਖਰ ਹੈ ਅਤੇ ਸਭ ਤੋਂ ਲੰਬਾ 5 ਅੱਖਰ ਹੈ, ਤਾਂ ਇਸ ਫਾਰਮੂਲੇ ਦੀ ਵਰਤੋਂ ਕਰੋ:
=CODE(MID(B2,1,1)) & CODE(MID(B2,2,1)) & CODE(MID(B2,3,1)) & IFERROR(CODE(MID(B2,3,1)),"") & IFERROR(CODE(MID(B2,4,1)),"")
=КОДСИМВ(ПСТР(B2;1;1)) & КОДСИМВ(ПСТР(B2;2;1)) & КОДСИМВ(ПСТР(B2;3;1)) & ЕСЛИОШИБКА(КОДСИМВ(ПСТР(B2;3;1));"") & ЕСЛИОШИБКА(КОДСИМВ(ПСТР(B2;4;1));"")
ਫੰਕਸ਼ਨ ਲਈ ਪੀਐਸਟੀਆਰ (MID) ਤੁਸੀਂ ਹੇਠ ਲਿਖੀਆਂ ਦਲੀਲਾਂ ਪ੍ਰਦਾਨ ਕਰਦੇ ਹੋ:
- ਪਹਿਲੀ ਦਲੀਲ - ਪਾਠ ਨੂੰ (ਟੈਕਸਟ) ਉਹ ਟੈਕਸਟ ਜਾਂ ਸੈੱਲ ਸੰਦਰਭ ਹੈ ਜਿਸ ਵਿੱਚ ਅੱਖਰ ਸ਼ਾਮਲ ਕੀਤੇ ਜਾਣੇ ਹਨ (ਸਾਡੇ ਕੇਸ ਵਿੱਚ ਇਹ B2 ਹੈ)
- ਪਹਿਲੀ ਦਲੀਲ - start_num (start_position) ਉਹਨਾਂ ਅੱਖਰਾਂ ਵਿੱਚੋਂ ਪਹਿਲੇ ਦੀ ਸਥਿਤੀ ਹੈ ਜਿਸਨੂੰ ਐਕਸਟਰੈਕਟ ਕੀਤਾ ਜਾਣਾ ਹੈ। ਤੁਸੀਂ ਦਾਖਲ ਹੋ 1 ਪਹਿਲੇ ਫੰਕਸ਼ਨ ਵਿੱਚ ਪੀਐਸਟੀਆਰ, 2 - ਦੂਜੇ ਫੰਕਸ਼ਨ ਵਿੱਚ ਪੀਐਸਟੀਆਰ ਆਦਿ
- ਪਹਿਲੀ ਦਲੀਲ - ਨੰਬਰ_ਅੱਖਰ (ਅੱਖਰਾਂ ਦੀ_ਨੰਬਰ) - ਟੈਕਸਟ ਤੋਂ ਐਕਸਟਰੈਕਟ ਕਰਨ ਲਈ ਅੱਖਰਾਂ ਦੀ ਸੰਖਿਆ ਨਿਸ਼ਚਿਤ ਕਰਦਾ ਹੈ। ਕਿਉਂਕਿ ਸਾਨੂੰ ਹਰ ਸਮੇਂ ਸਿਰਫ 1 ਅੱਖਰ ਦੀ ਲੋੜ ਹੁੰਦੀ ਹੈ, ਸਾਰੇ ਫੰਕਸ਼ਨਾਂ ਵਿੱਚ ਅਸੀਂ ਲਿਖਦੇ ਹਾਂ 1.
ਸੀਮਾ ਫੰਕਸ਼ਨ ਵੀਪੀਆਰ ਐਕਸਲ ਵਿੱਚ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਖੋਜਾਂ ਲਈ ਸਭ ਤੋਂ ਵਧੀਆ ਹੱਲ ਨਹੀਂ ਹੈ। ਪਹਿਲਾਂ, ਇੱਕ ਸਹਾਇਕ ਕਾਲਮ ਜੋੜਨ ਦੀ ਲੋੜ ਹੈ। ਦੂਜਾ, ਫਾਰਮੂਲਾ ਸਿਰਫ ਤਾਂ ਹੀ ਚੰਗਾ ਕੰਮ ਕਰਦਾ ਹੈ ਜੇਕਰ ਡੇਟਾ ਸਮਰੂਪ ਹੈ, ਜਾਂ ਖੋਜੇ ਗਏ ਮੁੱਲਾਂ ਵਿੱਚ ਅੱਖਰਾਂ ਦੀ ਸਹੀ ਸੰਖਿਆ ਜਾਣੀ ਜਾਂਦੀ ਹੈ। ਜੇ ਇਹ ਤੁਹਾਡਾ ਕੇਸ ਨਹੀਂ ਹੈ, ਤਾਂ ਅਸੀਂ ਹੇਠਾਂ ਦਿਖਾਏ ਗਏ ਹੱਲਾਂ ਵਿੱਚੋਂ ਇੱਕ ਦੀ ਵਰਤੋਂ ਕਰਨਾ ਬਿਹਤਰ ਹੈ।
ਕੇਸ ਸੰਵੇਦਨਸ਼ੀਲ ਖੋਜ ਲਈ ਲੁੱਕਅੱਪ ਫੰਕਸ਼ਨ
ਫੰਕਸ਼ਨ VIEW ਦੇਖੋ (LOOKUP) ਨਾਲ ਸਬੰਧਤ ਹੈ ਵੀਪੀਆਰ, ਹਾਲਾਂਕਿ ਇਸਦਾ ਸੰਟੈਕਸ ਸਹਾਇਕ ਕਾਲਮ ਨੂੰ ਸ਼ਾਮਲ ਕੀਤੇ ਬਿਨਾਂ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਖੋਜਾਂ ਦੀ ਆਗਿਆ ਦਿੰਦਾ ਹੈ। ਅਜਿਹਾ ਕਰਨ ਲਈ, ਵਰਤੋ VIEW ਦੇਖੋ ਫੰਕਸ਼ਨ ਦੇ ਨਾਲ ਮਿਲਾ ਕੇ ਬਿਲਕੁਲ (ਸਟੀਕ)।
ਜੇ ਅਸੀਂ ਪਿਛਲੀ ਉਦਾਹਰਨ (ਇੱਕ ਸਹਾਇਕ ਕਾਲਮ ਤੋਂ ਬਿਨਾਂ) ਤੋਂ ਡੇਟਾ ਲੈਂਦੇ ਹਾਂ, ਤਾਂ ਹੇਠਾਂ ਦਿੱਤਾ ਫਾਰਮੂਲਾ ਕੰਮ ਨਾਲ ਸਿੱਝੇਗਾ:
=LOOKUP(TRUE,EXACT($A$2:$A$7,$F$2),$B$2:$B$7)
=ПРОСМОТР(ИСТИНА;СОВПАД($A$2:$A$7;$F$2);$B$2:$B$7)
ਫਾਰਮੂਲਾ ਰੇਂਜ ਵਿੱਚ ਖੋਜ ਕਰਦਾ ਹੈ ਏ 2: ਏ 7 ਸੈੱਲ ਮੁੱਲ ਨਾਲ ਸਟੀਕ ਮੇਲ F2 ਕੇਸ ਸੰਵੇਦਨਸ਼ੀਲ ਅਤੇ ਉਸੇ ਕਤਾਰ ਦੇ ਕਾਲਮ B ਤੋਂ ਮੁੱਲ ਵਾਪਸ ਕਰਦਾ ਹੈ।
ਪਸੰਦ ਹੈ ਵੀਪੀਆਰਫੰਕਸ਼ਨ VIEW ਦੇਖੋ ਟੈਕਸਟ ਅਤੇ ਸੰਖਿਆਤਮਕ ਮੁੱਲਾਂ ਦੇ ਨਾਲ ਬਰਾਬਰ ਕੰਮ ਕਰਦਾ ਹੈ, ਜਿਵੇਂ ਕਿ ਤੁਸੀਂ ਹੇਠਾਂ ਦਿੱਤੇ ਸਕ੍ਰੀਨਸ਼ੌਟ ਵਿੱਚ ਦੇਖ ਸਕਦੇ ਹੋ:
ਮਹੱਤਵਪੂਰਨ! ਫੰਕਸ਼ਨ ਲਈ ਕ੍ਰਮ ਵਿੱਚ VIEW ਦੇਖੋ ਸਹੀ ਢੰਗ ਨਾਲ ਕੰਮ ਕੀਤਾ, ਲੁੱਕਅੱਪ ਕਾਲਮ ਵਿੱਚ ਮੁੱਲਾਂ ਨੂੰ ਵਧਦੇ ਕ੍ਰਮ ਵਿੱਚ ਕ੍ਰਮਬੱਧ ਕੀਤਾ ਜਾਣਾ ਚਾਹੀਦਾ ਹੈ, ਭਾਵ ਸਭ ਤੋਂ ਛੋਟੇ ਤੋਂ ਵੱਡੇ ਤੱਕ।
ਮੈਨੂੰ ਸੰਖੇਪ ਵਿੱਚ ਦੱਸਣਾ ਚਾਹੀਦਾ ਹੈ ਕਿ ਫੰਕਸ਼ਨ ਕਿਵੇਂ ਕੰਮ ਕਰਦਾ ਹੈ ਬਿਲਕੁਲ ਉੱਪਰ ਦਿਖਾਏ ਗਏ ਫਾਰਮੂਲੇ ਵਿੱਚ, ਕਿਉਂਕਿ ਇਹ ਮੁੱਖ ਬਿੰਦੂ ਹੈ।
ਫੰਕਸ਼ਨ ਬਿਲਕੁਲ 1st ਅਤੇ 2nd ਆਰਗੂਮੈਂਟਾਂ ਵਿੱਚ ਦੋ ਟੈਕਸਟ ਮੁੱਲਾਂ ਦੀ ਤੁਲਨਾ ਕਰਦਾ ਹੈ ਅਤੇ ਜੇਕਰ ਉਹ ਬਿਲਕੁਲ ਇੱਕੋ ਜਿਹੇ ਹਨ ਤਾਂ TRUE ਵਾਪਸ ਕਰਦਾ ਹੈ, ਜਾਂ FALSE ਜੇਕਰ ਉਹ ਨਹੀਂ ਹਨ। ਇਹ ਸਾਡੇ ਲਈ ਮਹੱਤਵਪੂਰਨ ਹੈ ਕਿ ਫੰਕਸ਼ਨ ਬਿਲਕੁਲ ਕੇਸ ਸੰਵੇਦਨਸ਼ੀਲ.
ਆਓ ਦੇਖੀਏ ਕਿ ਸਾਡਾ ਫਾਰਮੂਲਾ ਕਿਵੇਂ ਕੰਮ ਕਰਦਾ ਹੈ ਦੇਖੋ+ਸਹੀ:
=LOOKUP(TRUE,EXACT($A$2:$A$7,$F$2),$B$2:$B$7)
=ПРОСМОТР(ИСТИНА;СОВПАД($A$2:$A$7;$F$2);$B$2:$B$7)
- ਫੰਕਸ਼ਨ ਬਿਲਕੁਲ ਸੈੱਲ ਮੁੱਲ ਦੀ ਤੁਲਨਾ ਕਰਦਾ ਹੈ F2 ਇੱਕ ਕਾਲਮ ਵਿੱਚ ਸਾਰੇ ਤੱਤਾਂ ਦੇ ਨਾਲ A (A2:A7)। ਜੇਕਰ ਕੋਈ ਸਟੀਕ ਮੇਲ ਮਿਲਦਾ ਹੈ ਤਾਂ TRUE ਦਿੰਦਾ ਹੈ, ਨਹੀਂ ਤਾਂ FALSE।
- ਕਿਉਂਕਿ ਤੁਸੀਂ ਪਹਿਲਾ ਫੰਕਸ਼ਨ ਆਰਗੂਮੈਂਟ ਦਿੰਦੇ ਹੋ VIEW ਦੇਖੋ ਮੁੱਲ TRUE, ਇਹ ਨਿਰਧਾਰਤ ਕਾਲਮ (ਸਾਡੇ ਕੇਸ ਵਿੱਚ, ਕਾਲਮ B) ਤੋਂ ਸੰਬੰਧਿਤ ਮੁੱਲ ਨੂੰ ਸਿਰਫ਼ ਤਾਂ ਹੀ ਕੱਢਦਾ ਹੈ ਜੇਕਰ ਕੋਈ ਸਟੀਕ ਮੇਲ ਮਿਲਦਾ ਹੈ, ਕੇਸ ਸੰਵੇਦਨਸ਼ੀਲ।
ਮੈਨੂੰ ਉਮੀਦ ਹੈ ਕਿ ਇਹ ਵਿਆਖਿਆ ਸਪਸ਼ਟ ਸੀ ਅਤੇ ਹੁਣ ਤੁਸੀਂ ਮੁੱਖ ਵਿਚਾਰ ਨੂੰ ਸਮਝ ਗਏ ਹੋ। ਜੇ ਅਜਿਹਾ ਹੈ, ਤਾਂ ਤੁਹਾਨੂੰ ਹੋਰ ਫੰਕਸ਼ਨਾਂ ਵਿੱਚ ਕੋਈ ਮੁਸ਼ਕਲ ਨਹੀਂ ਹੋਵੇਗੀ, ਜਿਸਦਾ ਅਸੀਂ ਅੱਗੇ ਵਿਸ਼ਲੇਸ਼ਣ ਕਰਾਂਗੇ, ਕਿਉਂਕਿ. ਉਹ ਸਾਰੇ ਇੱਕੋ ਸਿਧਾਂਤ 'ਤੇ ਕੰਮ ਕਰਦੇ ਹਨ।
ਸੀਮਾ ਲੁੱਕਅਪ ਕਾਲਮ ਵਿੱਚ ਡੇਟਾ ਨੂੰ ਵੱਧਦੇ ਕ੍ਰਮ ਵਿੱਚ ਕ੍ਰਮਬੱਧ ਕੀਤਾ ਜਾਣਾ ਚਾਹੀਦਾ ਹੈ।
SUMPRODUCT - ਟੈਕਸਟ ਮੁੱਲ ਲੱਭਦਾ ਹੈ, ਕੇਸ ਸੰਵੇਦਨਸ਼ੀਲ, ਪਰ ਸਿਰਫ਼ ਨੰਬਰ ਹੀ ਦਿੰਦਾ ਹੈ
ਜਿਵੇਂ ਕਿ ਤੁਸੀਂ ਸਿਰਲੇਖ ਤੋਂ ਪਹਿਲਾਂ ਹੀ ਸਮਝ ਗਏ ਹੋ, SUMPRODUCT (SUMPRODUCT) ਇੱਕ ਹੋਰ ਐਕਸਲ ਫੰਕਸ਼ਨ ਹੈ ਜੋ ਤੁਹਾਨੂੰ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਖੋਜ ਕਰਨ ਵਿੱਚ ਮਦਦ ਕਰੇਗਾ, ਪਰ ਸਿਰਫ ਸੰਖਿਆਤਮਕ ਮੁੱਲ ਵਾਪਸ ਕਰੇਗਾ। ਜੇ ਇਹ ਵਿਕਲਪ ਤੁਹਾਡੇ ਲਈ ਅਨੁਕੂਲ ਨਹੀਂ ਹੈ, ਤਾਂ ਤੁਸੀਂ ਤੁਰੰਤ ਬੰਡਲ 'ਤੇ ਜਾ ਸਕਦੇ ਹੋ INDEX+MATCH, ਜੋ ਕਿ ਕਿਸੇ ਵੀ ਕੇਸ ਅਤੇ ਕਿਸੇ ਵੀ ਡਾਟਾ ਕਿਸਮ ਲਈ ਇੱਕ ਹੱਲ ਦਿੰਦਾ ਹੈ.
ਪਹਿਲਾਂ, ਮੈਨੂੰ ਇਸ ਫੰਕਸ਼ਨ ਦੇ ਸੰਟੈਕਸ ਦੀ ਸੰਖੇਪ ਵਿੱਚ ਵਿਆਖਿਆ ਕਰਨ ਦਿਓ, ਇਹ ਤੁਹਾਨੂੰ ਹੇਠ ਲਿਖੇ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਫਾਰਮੂਲੇ ਨੂੰ ਬਿਹਤਰ ਢੰਗ ਨਾਲ ਸਮਝਣ ਵਿੱਚ ਮਦਦ ਕਰੇਗਾ।
ਫੰਕਸ਼ਨ SUMPRODUCT ਦਿੱਤੇ ਐਰੇ ਦੇ ਤੱਤਾਂ ਨੂੰ ਗੁਣਾ ਕਰਦਾ ਹੈ ਅਤੇ ਨਤੀਜਿਆਂ ਦਾ ਜੋੜ ਦਿੰਦਾ ਹੈ। ਸੰਟੈਕਸ ਇਸ ਤਰ੍ਹਾਂ ਦਿਖਾਈ ਦਿੰਦਾ ਹੈ:
SUMPRODUCT(array1,[array2],[array3],...)
СУММПРОИЗВ(массив1;[массив2];[массив3];…)
ਕਿਉਂਕਿ ਸਾਨੂੰ ਇੱਕ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਖੋਜ ਦੀ ਲੋੜ ਹੈ, ਅਸੀਂ ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰਦੇ ਹਾਂ ਬਿਲਕੁਲ ਗੁਣਕ ਵਿੱਚੋਂ ਇੱਕ ਵਜੋਂ ਪਿਛਲੀ ਉਦਾਹਰਨ ਤੋਂ (ਸਟੀਕ):
=SUMPRODUCT((EXACT($A$2:$A$7,$F$2)*($B$2:$B$7)))
=СУММПРОИЗВ((СОВПАД($A$2:$A$7;$F$2)*($B$2:$B$7)))
ਜਿਵੇਂ ਕਿ ਤੁਹਾਨੂੰ ਯਾਦ ਹੈ, ਬਿਲਕੁਲ ਸੈੱਲ ਮੁੱਲ ਦੀ ਤੁਲਨਾ ਕਰਦਾ ਹੈ F2 ਇੱਕ ਕਾਲਮ ਵਿੱਚ ਸਾਰੇ ਤੱਤਾਂ ਦੇ ਨਾਲ A. ਜੇਕਰ ਕੋਈ ਸਟੀਕ ਮੇਲ ਮਿਲਦਾ ਹੈ ਤਾਂ TRUE ਦਿੰਦਾ ਹੈ, ਨਹੀਂ ਤਾਂ FALSE। ਗਣਿਤਿਕ ਕਾਰਵਾਈਆਂ ਵਿੱਚ, Excel ਨੂੰ TRUE ਦੇ ਰੂਪ ਵਿੱਚ ਲੈਂਦਾ ਹੈ 1, ਅਤੇ ਲਈ FALSE 0ਹੋਰ SUMPRODUCT ਇਹਨਾਂ ਸੰਖਿਆਵਾਂ ਨੂੰ ਗੁਣਾ ਕਰਦਾ ਹੈ ਅਤੇ ਨਤੀਜਿਆਂ ਨੂੰ ਜੋੜਦਾ ਹੈ।
ਜ਼ੀਰੋ ਦੀ ਗਿਣਤੀ ਨਹੀਂ ਕੀਤੀ ਜਾਂਦੀ ਕਿਉਂਕਿ ਜਦੋਂ ਗੁਣਾ ਕੀਤਾ ਜਾਂਦਾ ਹੈ ਤਾਂ ਉਹ ਹਮੇਸ਼ਾ ਦਿੰਦੇ ਹਨ 0. ਆਉ ਇੱਕ ਡੂੰਘਾਈ ਨਾਲ ਵਿਚਾਰ ਕਰੀਏ ਕਿ ਕੀ ਹੁੰਦਾ ਹੈ ਜਦੋਂ ਇੱਕ ਕਾਲਮ ਵਿੱਚ ਇੱਕ ਸਹੀ ਮੇਲ ਹੁੰਦਾ ਹੈ A ਲੱਭਿਆ ਅਤੇ ਵਾਪਸ ਕੀਤਾ 1… ਫੰਕਸ਼ਨ SUMPRODUCT ਕਾਲਮ ਵਿੱਚ ਸੰਖਿਆ ਨੂੰ ਗੁਣਾ ਕਰਦਾ ਹੈ B on 1 ਅਤੇ ਨਤੀਜਾ ਵਾਪਸ ਕਰਦਾ ਹੈ - ਬਿਲਕੁਲ ਉਹੀ ਨੰਬਰ! ਇਹ ਇਸ ਲਈ ਹੈ ਕਿਉਂਕਿ ਦੂਜੇ ਉਤਪਾਦਾਂ ਦੇ ਨਤੀਜੇ ਜ਼ੀਰੋ ਹਨ, ਅਤੇ ਉਹ ਨਤੀਜੇ ਵਾਲੇ ਜੋੜ ਨੂੰ ਪ੍ਰਭਾਵਿਤ ਨਹੀਂ ਕਰਦੇ ਹਨ।
ਬਦਕਿਸਮਤੀ ਨਾਲ ਫੰਕਸ਼ਨ SUMPRODUCT ਟੈਕਸਟ ਮੁੱਲਾਂ ਅਤੇ ਤਾਰੀਖਾਂ ਨਾਲ ਕੰਮ ਨਹੀਂ ਕਰ ਸਕਦਾ ਕਿਉਂਕਿ ਉਹਨਾਂ ਨੂੰ ਗੁਣਾ ਨਹੀਂ ਕੀਤਾ ਜਾ ਸਕਦਾ। ਇਸ ਸਥਿਤੀ ਵਿੱਚ, ਤੁਹਾਨੂੰ ਇੱਕ ਗਲਤੀ ਸੁਨੇਹਾ ਮਿਲੇਗਾ #VALUE! (#VALUE!) ਜਿਵੇਂ ਇੱਕ ਸੈੱਲ ਵਿੱਚ F4 ਹੇਠ ਤਸਵੀਰ ਵਿੱਚ:
ਸੀਮਾ ਸਿਰਫ਼ ਸੰਖਿਆਤਮਕ ਮੁੱਲ ਦਿੰਦਾ ਹੈ।
INDEX + MATCH – ਕਿਸੇ ਵੀ ਡਾਟਾ ਕਿਸਮ ਲਈ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਖੋਜ
ਅੰਤ ਵਿੱਚ, ਅਸੀਂ ਇੱਕ ਅਸੀਮਤ ਅਤੇ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਖੋਜ ਫਾਰਮੂਲੇ ਦੇ ਨੇੜੇ ਹਾਂ ਜੋ ਕਿਸੇ ਵੀ ਡੇਟਾ ਸੈੱਟ ਨਾਲ ਕੰਮ ਕਰਦਾ ਹੈ।
ਇਹ ਉਦਾਹਰਨ ਆਖਰੀ ਆਉਂਦੀ ਹੈ, ਇਸ ਲਈ ਨਹੀਂ ਕਿ ਮਿਠਾਈ ਲਈ ਸਭ ਤੋਂ ਵਧੀਆ ਬਚਿਆ ਹੈ, ਪਰ ਕਿਉਂਕਿ ਪਿਛਲੀਆਂ ਉਦਾਹਰਣਾਂ ਤੋਂ ਪ੍ਰਾਪਤ ਗਿਆਨ ਤੁਹਾਨੂੰ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਫਾਰਮੂਲੇ ਨੂੰ ਬਿਹਤਰ ਅਤੇ ਤੇਜ਼ੀ ਨਾਲ ਸਮਝਣ ਵਿੱਚ ਮਦਦ ਕਰੇਗਾ। INDEX+MATCH (INDEX+MATCH)।
ਜਿਵੇਂ ਕਿ ਤੁਸੀਂ ਸ਼ਾਇਦ ਅਨੁਮਾਨ ਲਗਾਇਆ ਹੈ, ਫੰਕਸ਼ਨਾਂ ਦਾ ਸੁਮੇਲ ਹੋਰ ਉਜਾਗਰ и INDEX ਲਈ ਵਧੇਰੇ ਲਚਕਦਾਰ ਅਤੇ ਸ਼ਕਤੀਸ਼ਾਲੀ ਵਿਕਲਪ ਵਜੋਂ ਐਕਸਲ ਵਿੱਚ ਵਰਤਿਆ ਜਾਂਦਾ ਹੈ ਵੀਪੀਆਰ. VLOOKUP ਦੀ ਬਜਾਏ INDEX ਅਤੇ MATCH ਦੀ ਵਰਤੋਂ ਕਰਨਾ ਲੇਖ ਪੂਰੀ ਤਰ੍ਹਾਂ ਵਿਆਖਿਆ ਕਰੇਗਾ ਕਿ ਇਹ ਫੰਕਸ਼ਨ ਇਕੱਠੇ ਕਿਵੇਂ ਕੰਮ ਕਰਦੇ ਹਨ।
ਮੈਂ ਸਿਰਫ ਮੁੱਖ ਨੁਕਤਿਆਂ ਨੂੰ ਦੁਬਾਰਾ ਦੱਸਾਂਗਾ:
- ਫੰਕਸ਼ਨ ਹੋਰ ਉਜਾਗਰ (MATCH) ਇੱਕ ਦਿੱਤੀ ਰੇਂਜ ਵਿੱਚ ਇੱਕ ਮੁੱਲ ਦੀ ਖੋਜ ਕਰਦਾ ਹੈ ਅਤੇ ਇਸਦੀ ਸੰਬੰਧਿਤ ਸਥਿਤੀ, ਅਰਥਾਤ, ਕਤਾਰ ਅਤੇ/ਜਾਂ ਕਾਲਮ ਨੰਬਰ ਵਾਪਸ ਕਰਦਾ ਹੈ;
- ਅੱਗੇ, ਫੰਕਸ਼ਨ INDEX (INDEX) ਇੱਕ ਨਿਰਧਾਰਤ ਕਾਲਮ ਅਤੇ/ਜਾਂ ਕਤਾਰ ਤੋਂ ਇੱਕ ਮੁੱਲ ਵਾਪਸ ਕਰਦਾ ਹੈ।
ਫਾਰਮੂਲੇ ਨੂੰ INDEX+MATCH ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲਤਾ ਨਾਲ ਖੋਜ ਕਰ ਸਕਦਾ ਹੈ, ਤੁਹਾਨੂੰ ਇਸ ਵਿੱਚ ਸਿਰਫ਼ ਇੱਕ ਫੰਕਸ਼ਨ ਜੋੜਨ ਦੀ ਲੋੜ ਹੈ। ਇਹ ਅੰਦਾਜ਼ਾ ਲਗਾਉਣਾ ਔਖਾ ਨਹੀਂ ਹੈ ਕਿ ਇਹ ਦੁਬਾਰਾ ਕੀ ਹੈ ਬਿਲਕੁਲ (ਸਟੀਕ):
=INDEX($B$2:$B$7,MATCH(TRUE,EXACT($A$2:$A$7,$F$2),0))
=ИНДЕКС($B$2:$B$7;ПОИСКПОЗ(ИСТИНА;СОВПАД($A$2:$A$7;$F$2);0))
ਇਸ ਫਾਰਮੂਲੇ ਵਿੱਚ ਬਿਲਕੁਲ ਉਸੇ ਤਰ੍ਹਾਂ ਕੰਮ ਕਰਦਾ ਹੈ ਜਿਵੇਂ ਫੰਕਸ਼ਨ ਦੇ ਨਾਲ ਜੋੜਿਆ ਜਾਂਦਾ ਹੈ VIEW ਦੇਖੋ, ਅਤੇ ਉਹੀ ਨਤੀਜਾ ਦਿੰਦਾ ਹੈ:
ਨੋਟ ਕਰੋ ਕਿ ਫਾਰਮੂਲਾ INDEX+MATCH ਕਰਲੀ ਬਰੇਸ ਵਿੱਚ ਬੰਦ ਇੱਕ ਐਰੇ ਫਾਰਮੂਲਾ ਹੈ ਅਤੇ ਤੁਹਾਨੂੰ ਇਸਨੂੰ ਦਬਾ ਕੇ ਪੂਰਾ ਕਰਨਾ ਚਾਹੀਦਾ ਹੈ Ctrl + Shift + enter.
ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਖੋਜ ਲਈ INDEX+MATCH ਸਭ ਤੋਂ ਵਧੀਆ ਹੱਲ ਕਿਉਂ ਹੈ?
ਬੰਡਲ ਦੇ ਮੁੱਖ ਫਾਇਦੇ INDEX и ਹੋਰ ਉਜਾਗਰ:
- ਇਸਦੇ ਉਲਟ, ਸਹਾਇਕ ਕਾਲਮ ਨੂੰ ਜੋੜਨ ਦੀ ਲੋੜ ਨਹੀਂ ਹੈ ਵੀਪੀਆਰ.
- ਖੋਜ ਕਾਲਮ ਨੂੰ ਕ੍ਰਮਬੱਧ ਕਰਨ ਦੀ ਲੋੜ ਨਹੀਂ ਹੈ, ਉਲਟ VIEW ਦੇਖੋ.
- ਹਰ ਕਿਸਮ ਦੇ ਡੇਟਾ - ਨੰਬਰ, ਟੈਕਸਟ ਅਤੇ ਮਿਤੀਆਂ ਨਾਲ ਕੰਮ ਕਰਦਾ ਹੈ।
ਇਹ ਫਾਰਮੂਲਾ ਸੰਪੂਰਨ ਲੱਗਦਾ ਹੈ, ਹੈ ਨਾ? ਅਸਲ ਵਿੱਚ, ਇਹ ਨਹੀਂ ਹੈ। ਅਤੇ ਇਸੇ ਲਈ.
ਮੰਨ ਲਓ ਕਿ ਖੋਜ ਮੁੱਲ ਨਾਲ ਸੰਬੰਧਿਤ ਵਾਪਸੀ ਮੁੱਲ ਕਾਲਮ ਵਿੱਚ ਸੈੱਲ ਖਾਲੀ ਹੈ। ਫਾਰਮੂਲਾ ਕੀ ਨਤੀਜਾ ਵਾਪਸ ਕਰੇਗਾ? ਨਹੀਂ? ਆਓ ਦੇਖੀਏ ਕਿ ਫਾਰਮੂਲਾ ਅਸਲ ਵਿੱਚ ਕੀ ਵਾਪਸ ਕਰਦਾ ਹੈ:
ਓਹੋ, ਫਾਰਮੂਲਾ ਜ਼ੀਰੋ ਦਿੰਦਾ ਹੈ! ਜੇ ਤੁਸੀਂ ਸ਼ੁੱਧ ਪਾਠ ਮੁੱਲਾਂ ਨਾਲ ਕੰਮ ਕਰ ਰਹੇ ਹੋ ਤਾਂ ਇਹ ਇੱਕ ਵੱਡੀ ਸਮੱਸਿਆ ਨਹੀਂ ਹੋ ਸਕਦੀ. ਹਾਲਾਂਕਿ, ਜੇਕਰ ਸਾਰਣੀ ਵਿੱਚ "ਅਸਲ" ਜ਼ੀਰੋ ਸਮੇਤ ਸੰਖਿਆਵਾਂ ਹਨ, ਤਾਂ ਇਹ ਇੱਕ ਸਮੱਸਿਆ ਬਣ ਜਾਂਦੀ ਹੈ।
ਵਾਸਤਵ ਵਿੱਚ, ਹੋਰ ਸਾਰੇ ਲੁੱਕਅਪ ਫਾਰਮੂਲੇ (VLOOKUP, LOOKUP, ਅਤੇ SUMPRODUCT) ਜਿਨ੍ਹਾਂ ਬਾਰੇ ਅਸੀਂ ਪਹਿਲਾਂ ਚਰਚਾ ਕੀਤੀ ਸੀ ਉਹੀ ਵਿਵਹਾਰ ਕਰਦੇ ਹਨ। ਪਰ ਤੁਸੀਂ ਸੰਪੂਰਨ ਫਾਰਮੂਲਾ ਚਾਹੁੰਦੇ ਹੋ, ਠੀਕ ਹੈ?
ਇੱਕ ਫਾਰਮੂਲਾ ਕੇਸ ਸੰਵੇਦਨਸ਼ੀਲ ਬਣਾਉਣ ਲਈ INDEX+MATCH ਸੰਪੂਰਨ, ਇਸਨੂੰ ਇੱਕ ਫੰਕਸ਼ਨ ਵਿੱਚ ਪਾਓ IF (IF) ਜੋ ਵਾਪਸੀ ਮੁੱਲ ਦੇ ਨਾਲ ਇੱਕ ਸੈੱਲ ਦੀ ਜਾਂਚ ਕਰੇਗਾ ਅਤੇ ਇੱਕ ਖਾਲੀ ਨਤੀਜਾ ਵਾਪਸ ਕਰੇਗਾ ਜੇਕਰ ਇਹ ਖਾਲੀ ਹੈ:
=IF(INDIRECT("B"&(1+MATCH(TRUE,EXACT($A$2:$A$7,$G$2),0)))<>"",INDEX($B$2:$B$7, MATCH(TRUE,EXACT($A$2:$A$7,$G$2),0)),"")
=ЕСЛИ(ДВССЫЛ("B"&(1+ПОИСКПОЗ(ИСТИНА;СОВПАД($A$2:$A$7;$G$2);0)))<>"";ИНДЕКС($B$2:$B$7; ПОИСКПОЗ(ИСТИНА;СОВПАД($A$2:$A$7;$G$2);0));"")
ਇਸ ਫਾਰਮੂਲੇ ਵਿੱਚ:
- B ਵਾਪਸੀ ਮੁੱਲਾਂ ਵਾਲਾ ਇੱਕ ਕਾਲਮ ਹੈ
- 1+ ਇੱਕ ਸੰਖਿਆ ਹੈ ਜੋ ਫੰਕਸ਼ਨ ਦੁਆਰਾ ਵਾਪਸ ਕੀਤੇ ਸੈੱਲ ਦੀ ਰਿਸ਼ਤੇਦਾਰ ਸਥਿਤੀ ਨੂੰ ਮੋੜਦੀ ਹੈ ਹੋਰ ਉਜਾਗਰ, ਸੈੱਲ ਦੇ ਅਸਲ ਪਤੇ 'ਤੇ. ਉਦਾਹਰਨ ਲਈ, ਸਾਡੇ ਫੰਕਸ਼ਨ ਵਿੱਚ ਹੋਰ ਉਜਾਗਰ ਖੋਜ ਐਰੇ ਦਿੱਤਾ ਗਿਆ ਹੈ ਏ 2: ਏ 7, ਭਾਵ, ਸੈੱਲ ਦੀ ਰਿਸ਼ਤੇਦਾਰ ਸਥਿਤੀ A2 ਕਰੇਗਾ 1, ਕਿਉਂਕਿ ਇਹ ਐਰੇ ਵਿੱਚ ਪਹਿਲਾ ਹੈ। ਪਰ ਸੈੱਲ ਦੀ ਅਸਲ ਸਥਿਤੀ A2 ਕਾਲਮ ਵਿੱਚ ਹੈ 2, ਇਸ ਲਈ ਅਸੀਂ ਜੋੜਦੇ ਹਾਂ 1ਫਰਕ ਬਣਾਉਣ ਅਤੇ ਫੰਕਸ਼ਨ ਕਰਨ ਲਈ ਅਸਿੱਧੇ (ਅਸਿੱਧੇ) ਨੇ ਲੋੜੀਂਦੇ ਸੈੱਲ ਤੋਂ ਮੁੱਲ ਪ੍ਰਾਪਤ ਕੀਤਾ।
ਹੇਠਾਂ ਦਿੱਤੀਆਂ ਤਸਵੀਰਾਂ ਸਹੀ ਕੀਤੇ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਫਾਰਮੂਲੇ ਨੂੰ ਦਿਖਾਉਂਦੀਆਂ ਹਨ INDEX+MATCH ਕਾਰਵਾਈ ਵਿੱਚ. ਇਹ ਇੱਕ ਖਾਲੀ ਨਤੀਜਾ ਦਿੰਦਾ ਹੈ ਜੇਕਰ ਵਾਪਸ ਕੀਤਾ ਸੈੱਲ ਖਾਲੀ ਹੈ।
ਮੈਂ ਫਾਰਮੂਲੇ ਨੂੰ ਕਾਲਮਾਂ ਵਿੱਚ ਦੁਬਾਰਾ ਲਿਖਿਆ ਬੀ:ਡੀਸਕਰੀਨਸ਼ਾਟ 'ਤੇ ਫਾਰਮੂਲਾ ਪੱਟੀ ਨੂੰ ਫਿੱਟ ਕਰਨ ਲਈ।
ਫਾਰਮੂਲਾ ਵਾਪਸੀ 0ਜੇਕਰ ਵਾਪਸ ਕੀਤੇ ਸੈੱਲ ਵਿੱਚ ਜ਼ੀਰੋ ਹੈ।
ਜੇਕਰ ਤੁਸੀਂ ਲਿੰਕ ਚਾਹੁੰਦੇ ਹੋ INDEX и ਹੋਰ ਉਜਾਗਰ ਕੁਝ ਸੁਨੇਹਾ ਪ੍ਰਦਰਸ਼ਿਤ ਕਰਦਾ ਹੈ ਜਦੋਂ ਵਾਪਸੀ ਮੁੱਲ ਖਾਲੀ ਹੁੰਦਾ ਹੈ, ਤੁਸੀਂ ਇਸਨੂੰ ਫਾਰਮੂਲੇ ਦੇ ਆਖਰੀ ਕੋਟਸ ("") ਵਿੱਚ ਲਿਖ ਸਕਦੇ ਹੋ, ਉਦਾਹਰਨ ਲਈ, ਇਸ ਤਰ੍ਹਾਂ:
=IF(INDIRECT("D"&(1+MATCH(TRUE,EXACT($B$2:$B$7,$G$2),0)))<>"",INDEX($D$2:$D$7, MATCH(TRUE,EXACT($B$2:$B$7,$G$2),0)),"There is nothing to return, sorry.")
=ЕСЛИ(ДВССЫЛ("D"&(1+ПОИСКПОЗ(ИСТИНА;СОВПАД($B$2:$B$7;$G$2);0)))<>"";ИНДЕКС($D$2:$D$7; ПОИСКПОЗ(ИСТИНА;СОВПАД($B$2:$B$7;$G$2);0));"There is nothing to return, sorry.")
