ਸਮੱਗਰੀ
- ਕਈ ਮਾਪਦੰਡਾਂ ਦੁਆਰਾ ਐਕਸਲ ਵਿੱਚ ਖੋਜ ਕਰੋ
- ਅਸੀਂ VLOOKUP ਦੀ ਵਰਤੋਂ ਕਰਕੇ 2nd, 3rd, ਆਦਿ ਮੁੱਲਾਂ ਨੂੰ ਐਕਸਟਰੈਕਟ ਕਰਦੇ ਹਾਂ
- ਲੋੜੀਂਦੇ ਮੁੱਲ ਦੇ ਸਾਰੇ ਦੁਹਰਾਓ ਮੁੜ ਪ੍ਰਾਪਤ ਕਰੋ
- ਜਾਣੀ ਜਾਂਦੀ ਕਤਾਰ ਅਤੇ ਕਾਲਮ ਦੁਆਰਾ XNUMXD ਖੋਜ
- ਇੱਕ ਫਾਰਮੂਲੇ ਵਿੱਚ ਕਈ VLOOKUPs ਦੀ ਵਰਤੋਂ ਕਰਨਾ
- VLOOKUP ਅਤੇ INDIRECT ਦੀ ਵਰਤੋਂ ਕਰਦੇ ਹੋਏ ਵੱਖ-ਵੱਖ ਟੇਬਲਾਂ ਤੋਂ ਡੇਟਾ ਦਾ ਗਤੀਸ਼ੀਲ ਬਦਲ
ਫੰਕਸ਼ਨ ਉੱਤੇ ਸਾਡੇ ਟਿਊਟੋਰਿਅਲ ਦੇ ਦੂਜੇ ਭਾਗ ਵਿੱਚ ਵੀਪੀਆਰ (VLOOKUP) ਐਕਸਲ ਵਿੱਚ, ਅਸੀਂ ਕੁਝ ਉਦਾਹਰਣਾਂ ਦਾ ਵਿਸ਼ਲੇਸ਼ਣ ਕਰਾਂਗੇ ਜੋ ਤੁਹਾਡੀ ਸਾਰੀ ਸ਼ਕਤੀ ਨੂੰ ਨਿਰਦੇਸ਼ਤ ਕਰਨ ਵਿੱਚ ਮਦਦ ਕਰਨਗੇ ਵੀਪੀਆਰ ਸਭ ਤੋਂ ਅਭਿਲਾਸ਼ੀ ਐਕਸਲ ਕਾਰਜਾਂ ਨੂੰ ਹੱਲ ਕਰਨ ਲਈ। ਉਦਾਹਰਨਾਂ ਇਹ ਮੰਨਦੀਆਂ ਹਨ ਕਿ ਤੁਹਾਡੇ ਕੋਲ ਪਹਿਲਾਂ ਹੀ ਇਸ ਵਿਸ਼ੇਸ਼ਤਾ ਦੇ ਕੰਮ ਕਰਨ ਬਾਰੇ ਬੁਨਿਆਦੀ ਗਿਆਨ ਹੈ। ਜੇਕਰ ਨਹੀਂ, ਤਾਂ ਤੁਸੀਂ ਇਸ ਟਿਊਟੋਰਿਅਲ ਦੇ ਪਹਿਲੇ ਭਾਗ ਨਾਲ ਸ਼ੁਰੂ ਕਰਨ ਵਿੱਚ ਦਿਲਚਸਪੀ ਲੈ ਸਕਦੇ ਹੋ, ਜੋ ਸੰਟੈਕਸ ਅਤੇ ਬੁਨਿਆਦੀ ਵਰਤੋਂ ਦੀ ਵਿਆਖਿਆ ਕਰਦਾ ਹੈ। ਵੀਪੀਆਰ. ਖੈਰ, ਆਓ ਸ਼ੁਰੂ ਕਰੀਏ।
ਕਈ ਮਾਪਦੰਡਾਂ ਦੁਆਰਾ ਐਕਸਲ ਵਿੱਚ ਖੋਜ ਕਰੋ
ਫੰਕਸ਼ਨ ਵੀਪੀਆਰ ਐਕਸਲ ਵਿੱਚ ਇੱਕ ਡੇਟਾਬੇਸ ਵਿੱਚ ਇੱਕ ਖਾਸ ਮੁੱਲ ਲਈ ਖੋਜਾਂ ਕਰਨ ਲਈ ਇੱਕ ਅਸਲ ਸ਼ਕਤੀਸ਼ਾਲੀ ਸਾਧਨ ਹੈ। ਹਾਲਾਂਕਿ, ਇੱਥੇ ਇੱਕ ਮਹੱਤਵਪੂਰਣ ਸੀਮਾ ਹੈ - ਇਸਦਾ ਸੰਟੈਕਸ ਤੁਹਾਨੂੰ ਸਿਰਫ ਇੱਕ ਮੁੱਲ ਦੀ ਖੋਜ ਕਰਨ ਦੀ ਆਗਿਆ ਦਿੰਦਾ ਹੈ. ਜੇਕਰ ਤੁਸੀਂ ਕਈ ਸ਼ਰਤਾਂ ਦੁਆਰਾ ਖੋਜ ਕਰਨਾ ਚਾਹੁੰਦੇ ਹੋ ਤਾਂ ਕੀ ਹੋਵੇਗਾ? ਤੁਹਾਨੂੰ ਹੇਠ ਹੱਲ ਲੱਭ ਜਾਵੇਗਾ.
ਉਦਾਹਰਨ 1: 2 ਵੱਖ-ਵੱਖ ਮਾਪਦੰਡਾਂ ਦੁਆਰਾ ਖੋਜ ਕਰੋ
ਮੰਨ ਲਓ ਕਿ ਸਾਡੇ ਕੋਲ ਆਦੇਸ਼ਾਂ ਦੀ ਇੱਕ ਸੂਚੀ ਹੈ ਅਤੇ ਅਸੀਂ ਲੱਭਣਾ ਚਾਹੁੰਦੇ ਹਾਂ ਮਾਲ ਦੀ ਮਾਤਰਾ (ਮਾਤਰ), ਦੋ ਮਾਪਦੰਡਾਂ 'ਤੇ ਆਧਾਰਿਤ - ਗਾਹਕ ਦਾ ਨਾਮ (ਗਾਹਕ) и ਉਤਪਾਦ ਦਾ ਨਾਮ (ਉਤਪਾਦ)। ਮਾਮਲਾ ਇਸ ਤੱਥ ਦੁਆਰਾ ਗੁੰਝਲਦਾਰ ਹੈ ਕਿ ਹਰੇਕ ਖਰੀਦਦਾਰ ਨੇ ਕਈ ਕਿਸਮਾਂ ਦੇ ਸਾਮਾਨ ਦਾ ਆਰਡਰ ਦਿੱਤਾ ਹੈ, ਜਿਵੇਂ ਕਿ ਹੇਠਾਂ ਦਿੱਤੀ ਸਾਰਣੀ ਤੋਂ ਦੇਖਿਆ ਜਾ ਸਕਦਾ ਹੈ:
ਨਿਯਮਤ ਫੰਕਸ਼ਨ ਵੀਪੀਆਰ ਇਸ ਦ੍ਰਿਸ਼ ਵਿੱਚ ਕੰਮ ਨਹੀਂ ਕਰੇਗਾ ਕਿਉਂਕਿ ਇਹ ਦਿੱਤੇ ਗਏ ਲੁੱਕਅਪ ਮੁੱਲ ਨਾਲ ਮੇਲ ਖਾਂਦਾ ਪਹਿਲਾ ਮੁੱਲ ਵਾਪਸ ਕਰੇਗਾ। ਉਦਾਹਰਨ ਲਈ, ਜੇਕਰ ਤੁਸੀਂ ਕਿਸੇ ਵਸਤੂ ਦੀ ਮਾਤਰਾ ਜਾਣਨਾ ਚਾਹੁੰਦੇ ਹੋ ਮਿਠਾਈਆਂਖਰੀਦਦਾਰ ਦੁਆਰਾ ਆਰਡਰ ਕੀਤਾ ਜੇਰੇਮੀ ਹਿੱਲ, ਹੇਠ ਲਿਖੇ ਫਾਰਮੂਲੇ ਨੂੰ ਲਿਖੋ:
=VLOOKUP(B1,$A$5:$C$14,3,FALSE)
=ВПР(B1;$A$5:$C$14;3;ЛОЖЬ)
- ਇਹ ਫਾਰਮੂਲਾ ਨਤੀਜਾ ਵਾਪਸ ਕਰੇਗਾ 15ਉਤਪਾਦ ਦੇ ਅਨੁਸਾਰੀ ਸੇਬ, ਕਿਉਂਕਿ ਇਹ ਪਹਿਲਾ ਮੁੱਲ ਹੈ ਜੋ ਮੇਲ ਖਾਂਦਾ ਹੈ।
ਇੱਥੇ ਇੱਕ ਸਧਾਰਨ ਹੱਲ ਹੈ - ਇੱਕ ਵਾਧੂ ਕਾਲਮ ਬਣਾਓ ਜਿਸ ਵਿੱਚ ਸਾਰੇ ਲੋੜੀਂਦੇ ਮਾਪਦੰਡਾਂ ਨੂੰ ਜੋੜਨਾ ਹੈ। ਸਾਡੇ ਉਦਾਹਰਨ ਵਿੱਚ, ਇਹ ਕਾਲਮ ਹਨ ਗਾਹਕ ਦਾ ਨਾਮ (ਗਾਹਕ) и ਉਤਪਾਦ ਦਾ ਨਾਮ (ਉਤਪਾਦ)। ਇਹ ਨਾ ਭੁੱਲੋ ਕਿ ਵਿਲੀਨ ਕੀਤਾ ਕਾਲਮ ਹਮੇਸ਼ਾ ਖੋਜ ਰੇਂਜ ਵਿੱਚ ਸਭ ਤੋਂ ਖੱਬੇ ਕਾਲਮ ਹੋਣਾ ਚਾਹੀਦਾ ਹੈ, ਕਿਉਂਕਿ ਇਹ ਖੱਬੇ ਕਾਲਮ ਹੈ ਜੋ ਫੰਕਸ਼ਨ ਵੀਪੀਆਰ ਮੁੱਲ ਦੀ ਤਲਾਸ਼ ਕਰਦੇ ਸਮੇਂ ਦਿਖਾਈ ਦਿੰਦਾ ਹੈ।
ਇਸ ਲਈ, ਤੁਸੀਂ ਸਾਰਣੀ ਵਿੱਚ ਇੱਕ ਸਹਾਇਕ ਕਾਲਮ ਜੋੜਦੇ ਹੋ ਅਤੇ ਇਸਦੇ ਸਾਰੇ ਸੈੱਲਾਂ ਉੱਤੇ ਹੇਠਾਂ ਦਿੱਤੇ ਫਾਰਮੂਲੇ ਦੀ ਨਕਲ ਕਰਦੇ ਹੋ: =B2&C2. ਜੇਕਰ ਤੁਸੀਂ ਸਤਰ ਨੂੰ ਵਧੇਰੇ ਪੜ੍ਹਨਯੋਗ ਬਣਾਉਣਾ ਚਾਹੁੰਦੇ ਹੋ, ਤਾਂ ਤੁਸੀਂ ਸੰਯੁਕਤ ਮੁੱਲਾਂ ਨੂੰ ਸਪੇਸ ਨਾਲ ਵੱਖ ਕਰ ਸਕਦੇ ਹੋ: =B2&» «&C2. ਉਸ ਤੋਂ ਬਾਅਦ, ਤੁਸੀਂ ਹੇਠਾਂ ਦਿੱਤੇ ਫਾਰਮੂਲੇ ਦੀ ਵਰਤੋਂ ਕਰ ਸਕਦੇ ਹੋ:
=VLOOKUP("Jeremy Hill Sweets",$A$7:$D$18,4,FALSE)
=ВПР("Jeremy Hill Sweets";$A$7:$D$18;4;ЛОЖЬ)
or
=VLOOKUP(B1,$A$7:$D$18,4,FALSE)
=ВПР(B1;$A$7:$D$18;4;ЛОЖЬ)
ਸੈੱਲ ਕਿੱਥੇ ਹੈ B1 ਆਰਗੂਮੈਂਟ ਦਾ ਜੋੜ ਮੁੱਲ ਰੱਖਦਾ ਹੈ ਲੁਕਿੰਗ_ਲੈਵਲ (lookup_value) ਅਤੇ 4 - ਦਲੀਲ col_index_num (column_number), ਅਰਥਾਤ ਕਾਲਮ ਦੀ ਸੰਖਿਆ ਜਿਸ ਵਿੱਚ ਡਾਟਾ ਪ੍ਰਾਪਤ ਕੀਤਾ ਜਾਣਾ ਹੈ।
ਉਦਾਹਰਨ 2: ਦੋ ਮਾਪਦੰਡਾਂ ਦੁਆਰਾ VLOOKUP ਸਾਰਣੀ ਨੂੰ ਕਿਸੇ ਹੋਰ ਸ਼ੀਟ 'ਤੇ ਦੇਖਿਆ ਜਾ ਰਿਹਾ ਹੈ
ਜੇਕਰ ਤੁਹਾਨੂੰ ਦੂਜੀ ਸਾਰਣੀ (ਲੁੱਕਅਪ ਟੇਬਲ) ਤੋਂ ਡਾਟਾ ਜੋੜ ਕੇ ਮੁੱਖ ਸਾਰਣੀ (ਮੁੱਖ ਸਾਰਣੀ) ਨੂੰ ਅੱਪਡੇਟ ਕਰਨ ਦੀ ਲੋੜ ਹੈ, ਜੋ ਕਿ ਕਿਸੇ ਹੋਰ ਸ਼ੀਟ ਜਾਂ ਕਿਸੇ ਹੋਰ ਐਕਸਲ ਵਰਕਬੁੱਕ ਵਿੱਚ ਸਥਿਤ ਹੈ, ਤਾਂ ਤੁਸੀਂ ਸਿੱਧੇ ਫਾਰਮੂਲੇ ਵਿੱਚ ਲੋੜੀਂਦਾ ਮੁੱਲ ਇਕੱਠਾ ਕਰ ਸਕਦੇ ਹੋ ਜੋ ਤੁਸੀਂ ਸੰਮਿਲਿਤ ਕਰਦੇ ਹੋ ਮੁੱਖ ਸਾਰਣੀ ਵਿੱਚ.
ਜਿਵੇਂ ਕਿ ਪਿਛਲੀ ਉਦਾਹਰਨ ਵਿੱਚ, ਤੁਹਾਨੂੰ ਸੰਯੁਕਤ ਮੁੱਲਾਂ ਦੇ ਨਾਲ ਲੁੱਕਅਪ ਟੇਬਲ ਵਿੱਚ ਇੱਕ ਸਹਾਇਕ ਕਾਲਮ ਦੀ ਲੋੜ ਹੋਵੇਗੀ। ਇਹ ਕਾਲਮ ਖੋਜ ਰੇਂਜ ਵਿੱਚ ਸਭ ਤੋਂ ਖੱਬਾ ਕਾਲਮ ਹੋਣਾ ਚਾਹੀਦਾ ਹੈ।
ਇਸ ਲਈ ਫਾਰਮੂਲਾ ਨਾਲ ਵੀਪੀਆਰ ਇਸ ਤਰ੍ਹਾਂ ਹੋ ਸਕਦਾ ਹੈ:
=VLOOKUP(B2&" "&C2,Orders!$A&$2:$D$2,4,FALSE)
=ВПР(B2&" "&C2;Orders!$A&$2:$D$2;4;ЛОЖЬ)
ਇੱਥੇ, ਕਾਲਮ B ਅਤੇ C ਵਿੱਚ ਕ੍ਰਮਵਾਰ ਗਾਹਕ ਨਾਮ ਅਤੇ ਉਤਪਾਦ ਦੇ ਨਾਮ, ਅਤੇ ਲਿੰਕ ਸ਼ਾਮਲ ਹਨ ਆਰਡਰ!$A&$2:$D$2 ਕਿਸੇ ਹੋਰ ਸ਼ੀਟ ਵਿੱਚ ਵੇਖਣ ਲਈ ਇੱਕ ਸਾਰਣੀ ਨੂੰ ਪਰਿਭਾਸ਼ਿਤ ਕਰਦਾ ਹੈ।
ਫਾਰਮੂਲੇ ਨੂੰ ਹੋਰ ਪੜ੍ਹਨਯੋਗ ਬਣਾਉਣ ਲਈ, ਤੁਸੀਂ ਵਿਊ ਰੇਂਜ ਨੂੰ ਇੱਕ ਨਾਮ ਦੇ ਸਕਦੇ ਹੋ, ਅਤੇ ਫਿਰ ਫਾਰਮੂਲਾ ਬਹੁਤ ਸਰਲ ਦਿਖਾਈ ਦੇਵੇਗਾ:
=VLOOKUP(B2&" "&C2,Orders,4,FALSE)
=ВПР(B2&" "&C2;Orders;4;ЛОЖЬ)
ਫਾਰਮੂਲੇ ਦੇ ਕੰਮ ਕਰਨ ਲਈ, ਸਾਰਣੀ ਦੇ ਸਭ ਤੋਂ ਖੱਬੇ ਕਾਲਮ ਵਿੱਚ ਜੋ ਮੁੱਲ ਤੁਸੀਂ ਦੇਖ ਰਹੇ ਹੋ, ਉਹਨਾਂ ਨੂੰ ਖੋਜ ਮਾਪਦੰਡ ਦੇ ਬਿਲਕੁਲ ਉਸੇ ਤਰੀਕੇ ਨਾਲ ਜੋੜਿਆ ਜਾਣਾ ਚਾਹੀਦਾ ਹੈ। ਉਪਰੋਕਤ ਚਿੱਤਰ ਵਿੱਚ, ਅਸੀਂ ਮੁੱਲਾਂ ਨੂੰ ਜੋੜ ਕੇ u2bu2band ਉਹਨਾਂ ਦੇ ਵਿਚਕਾਰ ਇੱਕ ਸਪੇਸ ਪਾਉਂਦੇ ਹਾਂ, ਉਸੇ ਤਰ੍ਹਾਂ ਤੁਹਾਨੂੰ ਫੰਕਸ਼ਨ ਦੀ ਪਹਿਲੀ ਆਰਗੂਮੈਂਟ (BXNUMX& “” & CXNUMX) ਵਿੱਚ ਕਰਨ ਦੀ ਲੋੜ ਹੈ।
ਯਾਦ ਰੱਖਣਾ! ਫੰਕਸ਼ਨ ਵੀਪੀਆਰ 255 ਅੱਖਰਾਂ ਤੱਕ ਸੀਮਿਤ, ਇਹ 255 ਅੱਖਰਾਂ ਤੋਂ ਵੱਧ ਲੰਬੇ ਮੁੱਲ ਦੀ ਖੋਜ ਨਹੀਂ ਕਰ ਸਕਦਾ ਹੈ। ਇਸ ਨੂੰ ਧਿਆਨ ਵਿੱਚ ਰੱਖੋ ਅਤੇ ਯਕੀਨੀ ਬਣਾਓ ਕਿ ਲੋੜੀਂਦੇ ਮੁੱਲ ਦੀ ਲੰਬਾਈ ਇਸ ਸੀਮਾ ਤੋਂ ਵੱਧ ਨਾ ਹੋਵੇ।
ਮੈਂ ਸਹਿਮਤ ਹਾਂ ਕਿ ਇੱਕ ਸਹਾਇਕ ਕਾਲਮ ਜੋੜਨਾ ਸਭ ਤੋਂ ਸ਼ਾਨਦਾਰ ਅਤੇ ਹਮੇਸ਼ਾ ਸਵੀਕਾਰਯੋਗ ਹੱਲ ਨਹੀਂ ਹੈ। ਤੁਸੀਂ ਸਹਾਇਕ ਕਾਲਮ ਤੋਂ ਬਿਨਾਂ ਵੀ ਅਜਿਹਾ ਕਰ ਸਕਦੇ ਹੋ, ਪਰ ਇਸਦੇ ਲਈ ਫੰਕਸ਼ਨਾਂ ਦੇ ਸੁਮੇਲ ਨਾਲ ਇੱਕ ਬਹੁਤ ਜ਼ਿਆਦਾ ਗੁੰਝਲਦਾਰ ਫਾਰਮੂਲੇ ਦੀ ਲੋੜ ਹੋਵੇਗੀ INDEX (INDEX) ਅਤੇ ਮੈਚ (ਹੋਰ ਪ੍ਰਗਟ)।
ਅਸੀਂ VLOOKUP ਦੀ ਵਰਤੋਂ ਕਰਕੇ 2nd, 3rd, ਆਦਿ ਮੁੱਲਾਂ ਨੂੰ ਐਕਸਟਰੈਕਟ ਕਰਦੇ ਹਾਂ
ਤੁਸੀਂ ਪਹਿਲਾਂ ਹੀ ਇਹ ਜਾਣਦੇ ਹੋ ਵੀਪੀਆਰ ਸਿਰਫ਼ ਇੱਕ ਮੇਲ ਖਾਂਦਾ ਮੁੱਲ ਵਾਪਸ ਕਰ ਸਕਦਾ ਹੈ, ਵਧੇਰੇ ਸਪਸ਼ਟ ਤੌਰ 'ਤੇ, ਪਹਿਲਾ ਪਾਇਆ ਗਿਆ। ਪਰ ਉਦੋਂ ਕੀ ਜੇ ਇਹ ਮੁੱਲ ਦੇਖੇ ਗਏ ਐਰੇ ਵਿੱਚ ਕਈ ਵਾਰ ਦੁਹਰਾਇਆ ਜਾਂਦਾ ਹੈ, ਅਤੇ ਤੁਸੀਂ ਉਹਨਾਂ ਵਿੱਚੋਂ ਦੂਜੇ ਜਾਂ ਤੀਜੇ ਨੂੰ ਐਕਸਟਰੈਕਟ ਕਰਨਾ ਚਾਹੁੰਦੇ ਹੋ? ਕੀ ਜੇ ਸਾਰੇ ਮੁੱਲ? ਸਮੱਸਿਆ ਗੁੰਝਲਦਾਰ ਜਾਪਦੀ ਹੈ, ਪਰ ਹੱਲ ਮੌਜੂਦ ਹੈ!
ਮੰਨ ਲਓ ਸਾਰਣੀ ਦੇ ਇੱਕ ਕਾਲਮ ਵਿੱਚ ਗਾਹਕਾਂ ਦੇ ਨਾਮ (ਗਾਹਕ ਨਾਮ) ਹਨ, ਅਤੇ ਦੂਜੇ ਕਾਲਮ ਵਿੱਚ ਉਹ ਉਤਪਾਦ (ਉਤਪਾਦ) ਹਨ ਜੋ ਉਹਨਾਂ ਨੇ ਖਰੀਦੇ ਹਨ। ਆਉ ਕਿਸੇ ਦਿੱਤੇ ਗਏ ਗਾਹਕ ਦੁਆਰਾ ਖਰੀਦੀ ਗਈ ਦੂਜੀ, ਤੀਜੀ ਅਤੇ ਚੌਥੀ ਆਈਟਮ ਨੂੰ ਲੱਭਣ ਦੀ ਕੋਸ਼ਿਸ਼ ਕਰੀਏ।
ਸਭ ਤੋਂ ਆਸਾਨ ਤਰੀਕਾ ਹੈ ਕਾਲਮ ਤੋਂ ਪਹਿਲਾਂ ਇੱਕ ਸਹਾਇਕ ਕਾਲਮ ਜੋੜਨਾ ਗਾਹਕ ਦਾ ਨਾਮ ਅਤੇ ਇਸਨੂੰ ਹਰੇਕ ਨਾਮ ਦੇ ਦੁਹਰਾਓ ਨੰਬਰ ਦੇ ਨਾਲ ਗਾਹਕ ਦੇ ਨਾਮਾਂ ਨਾਲ ਭਰੋ, ਉਦਾਹਰਨ ਲਈ, ਜੌਨ ਡੋ 1, ਜੌਨ ਡੋ 2 ਆਦਿ। ਅਸੀਂ ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰਕੇ ਨੰਬਰਿੰਗ ਦੇ ਨਾਲ ਟ੍ਰਿਕ ਕਰਾਂਗੇ COUNTIF (COUNTIF), ਇਹ ਦਿੱਤਾ ਗਿਆ ਹੈ ਕਿ ਗਾਹਕ ਦੇ ਨਾਮ ਕਾਲਮ B ਵਿੱਚ ਹਨ:
=B2&COUNTIF($B$2:B2,B2)
=B2&СЧЁТЕСЛИ($B$2:B2;B2)
ਉਸ ਤੋਂ ਬਾਅਦ ਤੁਸੀਂ ਆਮ ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰ ਸਕਦੇ ਹੋ ਵੀਪੀਆਰਲੋੜੀਂਦਾ ਆਰਡਰ ਲੱਭਣ ਲਈ. ਉਦਾਹਰਣ ਲਈ:
- ਲੱਭੋ 2-ਵਾਂ ਗਾਹਕ ਦੁਆਰਾ ਆਰਡਰ ਕੀਤੀ ਆਈਟਮ ਡੈਨ ਬ੍ਰਾਊਨ:
=VLOOKUP("Dan Brown2",$A$2:$C$16,3,FALSE)
=ВПР("Dan Brown2";$A$2:$C$16;3;ЛОЖЬ)
- ਲੱਭੋ 3-ਵਾਂ ਗਾਹਕ ਦੁਆਰਾ ਆਰਡਰ ਕੀਤੀ ਆਈਟਮ ਡੈਨ ਬ੍ਰਾਊਨ:
=VLOOKUP("Dan Brown3",$A$2:$C$16,3,FALSE)
=ВПР("Dan Brown3";$A$2:$C$16;3;ЛОЖЬ)
ਵਾਸਤਵ ਵਿੱਚ, ਤੁਸੀਂ ਟੈਕਸਟ ਦੀ ਬਜਾਏ ਇੱਕ ਸੈੱਲ ਸੰਦਰਭ ਨੂੰ ਖੋਜ ਮੁੱਲ ਦੇ ਰੂਪ ਵਿੱਚ ਦਾਖਲ ਕਰ ਸਕਦੇ ਹੋ, ਜਿਵੇਂ ਕਿ ਹੇਠਾਂ ਦਿੱਤੇ ਚਿੱਤਰ ਵਿੱਚ ਦਿਖਾਇਆ ਗਿਆ ਹੈ:
ਜੇ ਤੁਸੀਂ ਸਿਰਫ ਲੱਭ ਰਹੇ ਹੋ ਐਕਸਐਨਯੂਐਮਐਕਸ-ਈ ਦੁਹਰਾਓ, ਤੁਸੀਂ ਇੱਕ ਵਧੇਰੇ ਗੁੰਝਲਦਾਰ ਫਾਰਮੂਲਾ ਬਣਾ ਕੇ ਸਹਾਇਕ ਕਾਲਮ ਤੋਂ ਬਿਨਾਂ ਕਰ ਸਕਦੇ ਹੋ:
=IFERROR(VLOOKUP($F$2,INDIRECT("$B$"&(MATCH($F$2,Table4[Customer Name],0)+2)&":$C16"),2,FALSE),"")
=ЕСЛИОШИБКА(ВПР($F$2;ДВССЫЛ("$B$"&(ПОИСКПОЗ($F$2;Table4[Customer Name];0)+2)&":$C16");2;ИСТИНА);"")
ਇਸ ਫਾਰਮੂਲੇ ਵਿੱਚ:
- $F$2 - ਖਰੀਦਦਾਰ ਦਾ ਨਾਮ ਰੱਖਣ ਵਾਲਾ ਇੱਕ ਸੈੱਲ (ਇਹ ਬਦਲਿਆ ਨਹੀਂ ਹੈ, ਕਿਰਪਾ ਕਰਕੇ ਨੋਟ ਕਰੋ - ਲਿੰਕ ਪੂਰਨ ਹੈ);
- $B$ - ਕਾਲਮ ਗਾਹਕ ਦਾ ਨਾਮ;
- ਟੇਬਲ 4 - ਤੁਹਾਡੀ ਮੇਜ਼ (ਇਹ ਸਥਾਨ ਇੱਕ ਨਿਯਮਤ ਰੇਂਜ ਵੀ ਹੋ ਸਕਦਾ ਹੈ);
- $ C16 - ਤੁਹਾਡੀ ਟੇਬਲ ਜਾਂ ਰੇਂਜ ਦਾ ਅੰਤਮ ਸੈੱਲ।
ਇਹ ਫਾਰਮੂਲਾ ਸਿਰਫ਼ ਦੂਜਾ ਮੇਲ ਖਾਂਦਾ ਮੁੱਲ ਲੱਭਦਾ ਹੈ। ਜੇਕਰ ਤੁਹਾਨੂੰ ਬਾਕੀ ਦੇ ਦੁਹਰਾਓ ਨੂੰ ਕੱਢਣ ਦੀ ਲੋੜ ਹੈ, ਤਾਂ ਪਿਛਲੇ ਹੱਲ ਦੀ ਵਰਤੋਂ ਕਰੋ।
ਜੇਕਰ ਤੁਹਾਨੂੰ ਸਾਰੇ ਮੈਚਾਂ ਦੀ ਸੂਚੀ ਚਾਹੀਦੀ ਹੈ - ਫੰਕਸ਼ਨ ਵੀਪੀਆਰ ਇਹ ਇੱਕ ਸਹਾਇਕ ਨਹੀਂ ਹੈ, ਕਿਉਂਕਿ ਇਹ ਇੱਕ ਸਮੇਂ ਵਿੱਚ ਸਿਰਫ਼ ਇੱਕ ਮੁੱਲ ਵਾਪਸ ਕਰਦਾ ਹੈ - ਮਿਆਦ। ਪਰ ਐਕਸਲ ਦਾ ਇੱਕ ਫੰਕਸ਼ਨ ਹੈ INDEX (INDEX), ਜੋ ਇਸ ਕੰਮ ਨੂੰ ਆਸਾਨੀ ਨਾਲ ਨਿਪਟ ਸਕਦਾ ਹੈ। ਅਜਿਹਾ ਫਾਰਮੂਲਾ ਕਿਵੇਂ ਦਿਖਾਈ ਦੇਵੇਗਾ, ਤੁਸੀਂ ਹੇਠਾਂ ਦਿੱਤੀ ਉਦਾਹਰਣ ਵਿੱਚ ਸਿੱਖੋਗੇ।
ਲੋੜੀਂਦੇ ਮੁੱਲ ਦੇ ਸਾਰੇ ਦੁਹਰਾਓ ਮੁੜ ਪ੍ਰਾਪਤ ਕਰੋ
ਜਿਵੇਂ ਉੱਪਰ ਦੱਸਿਆ ਗਿਆ ਹੈ ਵੀਪੀਆਰ ਸਕੈਨ ਕੀਤੀ ਰੇਂਜ ਤੋਂ ਸਾਰੇ ਡੁਪਲੀਕੇਟ ਮੁੱਲ ਨਹੀਂ ਕੱਢ ਸਕਦੇ। ਅਜਿਹਾ ਕਰਨ ਲਈ, ਤੁਹਾਨੂੰ ਇੱਕ ਥੋੜ੍ਹਾ ਹੋਰ ਗੁੰਝਲਦਾਰ ਫਾਰਮੂਲਾ ਚਾਹੀਦਾ ਹੈ, ਜੋ ਕਿ ਕਈ ਐਕਸਲ ਫੰਕਸ਼ਨਾਂ ਤੋਂ ਬਣਿਆ ਹੈ, ਜਿਵੇਂ ਕਿ INDEX (INDEX), ਛੋਟਾ (ਛੋਟਾ) ਅਤੇ ROW (ਲਾਈਨ)
ਉਦਾਹਰਨ ਲਈ, ਹੇਠਾਂ ਦਿੱਤਾ ਫਾਰਮੂਲਾ B2:B2 ਰੇਂਜ ਵਿੱਚ ਸੈੱਲ F16 ਤੋਂ ਮੁੱਲ ਦੀਆਂ ਸਾਰੀਆਂ ਦੁਹਰਾਓ ਲੱਭਦਾ ਹੈ ਅਤੇ ਕਾਲਮ C ਵਿੱਚ ਇੱਕੋ ਕਤਾਰ ਤੋਂ ਨਤੀਜਾ ਦਿੰਦਾ ਹੈ।
{=IFERROR(INDEX($C$2:$C$16,SMALL(IF($F$2=B2:B16,ROW(C2:C16)-1,""),ROW()-3)),"")}
{=ЕСЛИОШИБКА(ИНДЕКС($C$2:$C$16;НАИМЕНЬШИЙ(ЕСЛИ($F$2=B2:B16;СТРОКА(C2:C16)-1;"");СТРОКА()-3));"")}
ਇਸ ਐਰੇ ਫਾਰਮੂਲੇ ਨੂੰ ਕਈ ਨਾਲ ਲੱਗਦੇ ਸੈੱਲਾਂ ਵਿੱਚ ਦਾਖਲ ਕਰੋ, ਜਿਵੇਂ ਕਿ ਸੈੱਲ F4: F8ਜਿਵੇਂ ਕਿ ਹੇਠਾਂ ਚਿੱਤਰ ਵਿੱਚ ਦਿਖਾਇਆ ਗਿਆ ਹੈ। ਸੈੱਲਾਂ ਦੀ ਸੰਖਿਆ ਖੋਜੇ ਮੁੱਲ ਦੇ ਦੁਹਰਾਓ ਦੀ ਵੱਧ ਤੋਂ ਵੱਧ ਸੰਭਾਵਿਤ ਸੰਖਿਆ ਦੇ ਬਰਾਬਰ ਜਾਂ ਵੱਧ ਹੋਣੀ ਚਾਹੀਦੀ ਹੈ। ਕਲਿੱਕ ਕਰਨਾ ਨਾ ਭੁੱਲੋ Ctrl + Shift + enterਐਰੇ ਫਾਰਮੂਲੇ ਨੂੰ ਸਹੀ ਢੰਗ ਨਾਲ ਦਾਖਲ ਕਰਨ ਲਈ.
ਜੇਕਰ ਤੁਸੀਂ ਇਹ ਸਮਝਣ ਵਿੱਚ ਦਿਲਚਸਪੀ ਰੱਖਦੇ ਹੋ ਕਿ ਇਹ ਕਿਵੇਂ ਕੰਮ ਕਰਦਾ ਹੈ, ਤਾਂ ਆਓ ਫਾਰਮੂਲੇ ਦੇ ਵੇਰਵਿਆਂ ਵਿੱਚ ਥੋੜਾ ਜਿਹਾ ਡੁਬਕੀ ਕਰੀਏ:
ਭਾਗ 1:
IF($F$2=B2:B16,ROW(C2:C16)-1,"")
ЕСЛИ($F$2=B2:B16;СТРОКА(C2:C16)-1;"")
$F$2=B2:B16 - ਸੈੱਲ F2 ਵਿੱਚ ਮੁੱਲ ਦੀ ਤੁਲਨਾ B2:B16 ਸੀਮਾ ਵਿੱਚ ਹਰੇਕ ਮੁੱਲ ਨਾਲ ਕਰੋ। ਜੇਕਰ ਕੋਈ ਮੇਲ ਮਿਲਦਾ ਹੈ, ਤਾਂ ਸਮੀਕਰਨ STRING(C2:C16)-1 ਸੰਬੰਧਿਤ ਲਾਈਨ ਦੀ ਸੰਖਿਆ ਵਾਪਸ ਕਰਦਾ ਹੈ (ਮੁੱਲ -1 ਤੁਹਾਨੂੰ ਸਿਰਲੇਖ ਲਾਈਨ ਨੂੰ ਸ਼ਾਮਲ ਨਾ ਕਰਨ ਦੀ ਇਜਾਜ਼ਤ ਦਿੰਦਾ ਹੈ). ਜੇਕਰ ਕੋਈ ਮੇਲ ਨਹੀਂ ਹੈ, ਫੰਕਸ਼ਨ IF (IF) ਇੱਕ ਖਾਲੀ ਸਤਰ ਵਾਪਸ ਕਰਦਾ ਹੈ।
ਫੰਕਸ਼ਨ ਨਤੀਜਾ IF (IF) ਅਜਿਹੀ ਹਰੀਜੱਟਲ ਐਰੇ ਹੋਵੇਗੀ: {1,"",3,"",5,"","","","","","",12,"","",""}
ਭਾਗ 2:
ROW()-3
СТРОКА()-3
ਇੱਥੇ ਫੰਕਸ਼ਨ ROW (ਲਾਈਨ) ਇੱਕ ਵਾਧੂ ਕਾਊਂਟਰ ਵਜੋਂ ਕੰਮ ਕਰਦੀ ਹੈ। ਕਿਉਂਕਿ ਫਾਰਮੂਲਾ ਸੈੱਲ F4:F9 ਵਿੱਚ ਕਾਪੀ ਕੀਤਾ ਗਿਆ ਹੈ, ਅਸੀਂ ਸੰਖਿਆ ਨੂੰ ਘਟਾਉਂਦੇ ਹਾਂ 3 ਮੁੱਲ ਪ੍ਰਾਪਤ ਕਰਨ ਲਈ ਫੰਕਸ਼ਨ ਨਤੀਜੇ ਤੋਂ 1 ਸੈੱਲ ਵਿੱਚ F4 (ਲਾਈਨ 4, ਘਟਾਓ 3) ਪ੍ਰਾਪਤ ਕਰਨ ਲਈ 2 ਸੈੱਲ ਵਿੱਚ F5 (ਲਾਈਨ 5, ਘਟਾਓ 3) ਅਤੇ ਹੋਰ।
ਭਾਗ 3:
SMALL(IF($F$2=B2:B16,ROW(C2:C16)-1,""),ROW()-3))
НАИМЕНЬШИЙ(ЕСЛИ($F$2=B2:B16;СТРОКА(C2:C16)-1;"");СТРОКА()-3))
ਫੰਕਸ਼ਨ ਛੋਟਾ (SMALL) ਵਾਪਸੀ n-ਓ ਡਾਟਾ ਐਰੇ ਵਿੱਚ ਸਭ ਤੋਂ ਛੋਟਾ ਮੁੱਲ। ਸਾਡੇ ਕੇਸ ਵਿੱਚ, ਕਿਹੜੀ ਸਥਿਤੀ (ਸਭ ਤੋਂ ਛੋਟੀ ਤੋਂ) ਵਾਪਸ ਕਰਨੀ ਹੈ ਫੰਕਸ਼ਨ ਦੁਆਰਾ ਨਿਰਧਾਰਤ ਕੀਤੀ ਜਾਂਦੀ ਹੈ ROW (ਲਾਈਨ) (ਭਾਗ 2 ਦੇਖੋ)। ਇਸ ਲਈ, ਇੱਕ ਸੈੱਲ ਲਈ F4 ਫੰਕਸ਼ਨ SMALL({ਐਰੇ},1) ਰਿਟਰਨ 1-ਵਾਂ (ਸਭ ਤੋਂ ਛੋਟਾ) ਐਰੇ ਤੱਤ, ਭਾਵ 1. ਸੈੱਲ ਲਈ F5 ਰਿਟਰਨ 2-ਵਾਂ ਐਰੇ ਵਿੱਚ ਸਭ ਤੋਂ ਛੋਟਾ ਤੱਤ, ਜੋ ਕਿ ਹੈ 3ਆਦਿ
ਭਾਗ 4:
INDEX($C$2:$C$16,SMALL(IF($F$2=B2:B16,ROW(C2:C16)-1,""),ROW()-3))
ИНДЕКС($C$2:$C$16;НАИМЕНЬШИЙ(ЕСЛИ($F$2=B2:B16;СТРОКА(C2:C16)-1;"");СТРОКА()-3))
ਫੰਕਸ਼ਨ INDEX (INDEX) ਸਿਰਫ਼ ਇੱਕ ਐਰੇ ਵਿੱਚ ਇੱਕ ਖਾਸ ਸੈੱਲ ਦਾ ਮੁੱਲ ਵਾਪਸ ਕਰਦਾ ਹੈ ਸੀ 2: ਸੀ 16. ਸੈੱਲ ਲਈ F4 ਫੰਕਸ਼ਨ ਸੂਚਕਾਂਕ($C$2:$C$16) ਵਾਪਸ ਆਵੇਗਾ ਸੇਬਲਈ F5 ਫੰਕਸ਼ਨ ਸੂਚਕਾਂਕ($C$2:$C$16) ਵਾਪਸ ਆਵੇਗਾ ਮਿਠਾਈਆਂ ਇਤਆਦਿ.
ਭਾਗ 5:
IFERROR()
ЕСЛИОШИБКА()
ਅੰਤ ਵਿੱਚ, ਅਸੀਂ ਫੰਕਸ਼ਨ ਦੇ ਅੰਦਰ ਫਾਰਮੂਲਾ ਰੱਖਦੇ ਹਾਂ IFERROR (IFERROR), ਕਿਉਂਕਿ ਤੁਹਾਨੂੰ ਗਲਤੀ ਸੁਨੇਹੇ ਤੋਂ ਖੁਸ਼ ਹੋਣ ਦੀ ਸੰਭਾਵਨਾ ਨਹੀਂ ਹੈ #AT (#N/A) ਜੇਕਰ ਸੈੱਲਾਂ ਦੀ ਸੰਖਿਆ ਜਿਸ ਵਿੱਚ ਫਾਰਮੂਲਾ ਕਾਪੀ ਕੀਤਾ ਗਿਆ ਹੈ, ਦੇਖੇ ਜਾ ਰਹੇ ਰੇਂਜ ਵਿੱਚ ਡੁਪਲੀਕੇਟ ਮੁੱਲਾਂ ਦੀ ਸੰਖਿਆ ਤੋਂ ਘੱਟ ਹੈ।
ਜਾਣੀ ਜਾਂਦੀ ਕਤਾਰ ਅਤੇ ਕਾਲਮ ਦੁਆਰਾ XNUMXD ਖੋਜ
ਐਕਸਲ ਵਿੱਚ ਇੱਕ XNUMXD ਖੋਜ ਕਰਨ ਵਿੱਚ ਇੱਕ ਜਾਣੀ ਜਾਂਦੀ ਕਤਾਰ ਅਤੇ ਕਾਲਮ ਨੰਬਰ ਦੁਆਰਾ ਇੱਕ ਮੁੱਲ ਦੀ ਖੋਜ ਕਰਨਾ ਸ਼ਾਮਲ ਹੁੰਦਾ ਹੈ। ਦੂਜੇ ਸ਼ਬਦਾਂ ਵਿੱਚ, ਤੁਸੀਂ ਇੱਕ ਖਾਸ ਕਤਾਰ ਅਤੇ ਕਾਲਮ ਦੇ ਇੰਟਰਸੈਕਸ਼ਨ 'ਤੇ ਸੈੱਲ ਮੁੱਲ ਨੂੰ ਐਕਸਟਰੈਕਟ ਕਰ ਰਹੇ ਹੋ।
ਤਾਂ, ਆਉ ਆਪਣੀ ਸਾਰਣੀ ਵੱਲ ਮੁੜਦੇ ਹਾਂ ਅਤੇ ਇੱਕ ਫੰਕਸ਼ਨ ਦੇ ਨਾਲ ਇੱਕ ਫਾਰਮੂਲਾ ਲਿਖਦੇ ਹਾਂ ਵੀਪੀਆਰ, ਜਿਸ ਵਿੱਚ ਮਾਰਚ ਵਿੱਚ ਵਿਕਣ ਵਾਲੇ ਨਿੰਬੂ ਦੀ ਕੀਮਤ ਬਾਰੇ ਜਾਣਕਾਰੀ ਮਿਲੇਗੀ।
ਇੱਕ XNUMXD ਖੋਜ ਕਰਨ ਦੇ ਕਈ ਤਰੀਕੇ ਹਨ. ਵਿਕਲਪਾਂ ਦੀ ਜਾਂਚ ਕਰੋ ਅਤੇ ਇੱਕ ਚੁਣੋ ਜੋ ਤੁਹਾਡੇ ਲਈ ਸਭ ਤੋਂ ਵਧੀਆ ਹੈ।
VLOOKUP ਅਤੇ MATCH ਫੰਕਸ਼ਨ
ਤੁਸੀਂ ਫੰਕਸ਼ਨਾਂ ਦਾ ਇੱਕ ਸਮੂਹ ਵਰਤ ਸਕਦੇ ਹੋ ਵੀਪੀਆਰ (VLOOKUP) ਅਤੇ ਹੋਰ ਉਜਾਗਰ (ਮੈਚ) ਖੇਤਰਾਂ ਦੇ ਇੰਟਰਸੈਕਸ਼ਨ 'ਤੇ ਮੁੱਲ ਲੱਭਣ ਲਈ ਉਤਪਾਦ ਦਾ ਨਾਮ (ਸਤਰ) ਅਤੇ ਮਹੀਨਾ ਸਵਾਲ ਵਿੱਚ ਐਰੇ ਦਾ (ਕਾਲਮ)
=VLOOKUP("Lemons",$A$2:$I$9,MATCH("Mar",$A$1:$I$1,0),FALSE)
=ВПР("Lemons";$A$2:$I$9;ПОИСКПОЗ("Mar";$A$1:$I$1;0);ЛОЖЬ)
ਉਪਰੋਕਤ ਫਾਰਮੂਲਾ ਇੱਕ ਨਿਯਮਤ ਫੰਕਸ਼ਨ ਹੈ ਵੀਪੀਆਰ, ਜੋ ਕਿ A2 ਤੋਂ A9 ਸੈੱਲਾਂ ਵਿੱਚ ਮੁੱਲ “Lemons” ਦਾ ਸਹੀ ਮੇਲ ਲੱਭਦਾ ਹੈ। ਪਰ ਕਿਉਂਕਿ ਤੁਸੀਂ ਨਹੀਂ ਜਾਣਦੇ ਕਿ ਮਾਰਚ ਦੀ ਵਿਕਰੀ ਕਿਸ ਕਾਲਮ ਵਿੱਚ ਹੈ, ਤੁਸੀਂ ਤੀਜੇ ਫੰਕਸ਼ਨ ਆਰਗੂਮੈਂਟ ਲਈ ਕਾਲਮ ਨੰਬਰ ਸੈੱਟ ਕਰਨ ਦੇ ਯੋਗ ਨਹੀਂ ਹੋਵੋਗੇ। ਵੀਪੀਆਰ. ਇਸ ਦੀ ਬਜਾਏ, ਫੰਕਸ਼ਨ ਵਰਤਿਆ ਗਿਆ ਹੈ ਹੋਰ ਉਜਾਗਰਇਸ ਕਾਲਮ ਨੂੰ ਪਰਿਭਾਸ਼ਿਤ ਕਰਨ ਲਈ.
MATCH("Mar",$A$1:$I$1,0)
ПОИСКПОЗ("Mar";$A$1:$I$1;0)
ਮਨੁੱਖੀ ਭਾਸ਼ਾ ਵਿੱਚ ਅਨੁਵਾਦ ਕੀਤੇ ਗਏ ਇਸ ਫਾਰਮੂਲੇ ਦਾ ਅਰਥ ਹੈ:
- ਅਸੀਂ ਪਾਤਰਾਂ ਦੀ ਤਲਾਸ਼ ਕਰ ਰਹੇ ਹਾਂ “ਮਾਰ” – ਦਲੀਲ ਲੁਕਿੰਗ_ਲੈਵਲ (lookup_value);
- A1 ਤੋਂ I1 ਤੱਕ ਸੈੱਲਾਂ ਵਿੱਚ ਖੋਜ ਕਰਨਾ - ਆਰਗੂਮੈਂਟ ਲੁੱਕਅੱਪ_ਐਰੇ (lookup_array);
- ਸਹੀ ਮੇਲ ਵਾਪਸ ਕਰਨਾ - ਦਲੀਲ match_type (match_type)।
ਦਾ ਇਸਤੇਮਾਲ ਕਰਕੇ 0 ਤੀਜੇ ਆਰਗੂਮੈਂਟ ਵਿੱਚ, ਤੁਸੀਂ ਫੰਕਸ਼ਨ ਕਹਿੰਦੇ ਹੋ ਹੋਰ ਉਜਾਗਰ ਪਹਿਲੇ ਮੁੱਲ ਦੀ ਭਾਲ ਕਰੋ ਜੋ ਤੁਹਾਡੇ ਦੁਆਰਾ ਲੱਭ ਰਹੇ ਮੁੱਲ ਨਾਲ ਬਿਲਕੁਲ ਮੇਲ ਖਾਂਦਾ ਹੈ। ਇਹ ਮੁੱਲ ਦੇ ਬਰਾਬਰ ਹੈ ਗਲਤ (FALSE) ਚੌਥੀ ਦਲੀਲ ਲਈ ਵੀਪੀਆਰ.
ਇਸ ਤਰ੍ਹਾਂ ਤੁਸੀਂ ਐਕਸਲ ਵਿੱਚ ਦੋ-ਪੱਖੀ ਖੋਜ ਫਾਰਮੂਲਾ ਬਣਾ ਸਕਦੇ ਹੋ, ਜਿਸਨੂੰ ਦੋ-ਅਯਾਮੀ ਖੋਜ ਜਾਂ ਦੋ-ਪੱਖੀ ਖੋਜ ਵੀ ਕਿਹਾ ਜਾਂਦਾ ਹੈ।
SUMPRODUCT ਫੰਕਸ਼ਨ
ਫੰਕਸ਼ਨ SUMPRODUCT (SUMPRODUCT) ਚੁਣੀਆਂ ਗਈਆਂ ਐਰੇ ਦੇ ਉਤਪਾਦਾਂ ਦਾ ਜੋੜ ਵਾਪਸ ਕਰਦਾ ਹੈ:
=SUMPRODUCT(($A$2:$A$9="Lemons")*($A$1:$I$1="Mar"),$A$2:$I$9)
=СУММПРОИЗВ(($A$2:$A$9="Lemons")*($A$1:$I$1="Mar");$A$2:$I$9)
INDEX ਅਤੇ MATCH ਫੰਕਸ਼ਨ
ਅਗਲੇ ਲੇਖ ਵਿੱਚ ਮੈਂ ਇਹਨਾਂ ਫੰਕਸ਼ਨਾਂ ਦੀ ਵਿਸਤਾਰ ਵਿੱਚ ਵਿਆਖਿਆ ਕਰਾਂਗਾ, ਇਸ ਲਈ ਹੁਣੇ ਤੁਸੀਂ ਇਸ ਫਾਰਮੂਲੇ ਦੀ ਨਕਲ ਕਰ ਸਕਦੇ ਹੋ:
=INDEX($A$2:$I$9,MATCH("Lemons",$A$2:$A$9,0),MATCH("Mar",$A$1:$I$1,0))
=ИНДЕКС($A$2:$I$9;ПОИСКПОЗ("Lemons";$A$2:$A$9;0);ПОИСКПОЗ("Mar";$A$1:$I$1;0))
ਨਾਮਿਤ ਰੇਂਜਾਂ ਅਤੇ ਇੰਟਰਸੈਕਸ਼ਨ ਓਪਰੇਟਰ
ਜੇਕਰ ਤੁਸੀਂ ਉਹਨਾਂ ਸਾਰੇ ਗੁੰਝਲਦਾਰ ਐਕਸਲ ਫਾਰਮੂਲਿਆਂ ਵਿੱਚ ਨਹੀਂ ਹੋ, ਤਾਂ ਤੁਹਾਨੂੰ ਇਹ ਵਿਜ਼ੂਅਲ ਅਤੇ ਯਾਦਗਾਰ ਤਰੀਕਾ ਪਸੰਦ ਹੋ ਸਕਦਾ ਹੈ:
- ਟੇਬਲ ਚੁਣੋ, ਟੈਬ ਖੋਲ੍ਹੋ ਫਾਰਮੂਲਿਆਂ (ਫਾਰਮੂਲੇ) ਅਤੇ ਕਲਿੱਕ ਕਰੋ ਚੋਣ ਤੋਂ ਬਣਾਓ (ਚੋਣ ਤੋਂ ਬਣਾਓ)।
- ਬਕਸੇ ਚੈੱਕ ਕਰੋ ਸਿਖਰ ਦੀ ਕਤਾਰ (ਉਪਰੋਕਤ ਲਾਈਨ 'ਤੇ) ਅਤੇ ਖੱਬਾ ਕਾਲਮ (ਖੱਬੇ ਪਾਸੇ ਦੇ ਕਾਲਮ ਵਿੱਚ)। ਮਾਈਕਰੋਸਾਫਟ ਐਕਸਲ ਤੁਹਾਡੀ ਸਪ੍ਰੈਡਸ਼ੀਟ ਦੇ ਉੱਪਰੀ ਕਤਾਰ ਅਤੇ ਖੱਬੇ ਕਾਲਮ ਵਿੱਚ ਮੁੱਲਾਂ ਤੋਂ ਰੇਂਜਾਂ ਨੂੰ ਨਾਮ ਨਿਰਧਾਰਤ ਕਰੇਗਾ। ਹੁਣ ਤੁਸੀਂ ਫਾਰਮੂਲੇ ਬਣਾਏ ਬਿਨਾਂ ਇਹਨਾਂ ਨਾਮਾਂ ਦੀ ਵਰਤੋਂ ਕਰਕੇ ਖੋਜ ਕਰ ਸਕਦੇ ਹੋ।
- ਕਿਸੇ ਵੀ ਖਾਲੀ ਸੈੱਲ ਵਿੱਚ, ਲਿਖੋ = ਕਤਾਰ_ਨਾਮ ਕਾਲਮ_ਨਾਮ, ਉਦਾਹਰਨ ਲਈ ਇਸ ਤਰ੍ਹਾਂ:
= ਨਿੰਬੂ ਮਾਰ
… ਜਾਂ ਉਲਟ:
= ਮਾਰ ਨਿੰਬੂ
ਯਾਦ ਰੱਖੋ ਕਿ ਕਤਾਰ ਅਤੇ ਕਾਲਮ ਦੇ ਨਾਮ ਇੱਕ ਸਪੇਸ ਦੁਆਰਾ ਵੱਖ ਕੀਤੇ ਜਾਣੇ ਚਾਹੀਦੇ ਹਨ, ਜੋ ਕਿ ਇਸ ਕੇਸ ਵਿੱਚ ਇੰਟਰਸੈਕਸ਼ਨ ਓਪਰੇਟਰ ਵਾਂਗ ਕੰਮ ਕਰਦਾ ਹੈ।
ਜਦੋਂ ਤੁਸੀਂ ਕੋਈ ਨਾਮ ਦਰਜ ਕਰਦੇ ਹੋ, ਤਾਂ Microsoft Excel ਮੇਲ ਖਾਂਦੇ ਨਾਵਾਂ ਦੀ ਸੂਚੀ ਦੇ ਨਾਲ ਇੱਕ ਟੂਲਟਿਪ ਦਿਖਾਏਗਾ, ਜਿਵੇਂ ਕਿ ਤੁਸੀਂ ਇੱਕ ਫਾਰਮੂਲਾ ਦਾਖਲ ਕਰਦੇ ਹੋ।
- ਪ੍ਰੈਸ ਦਿਓ ਅਤੇ ਨਤੀਜਾ ਚੈੱਕ ਕਰੋ
ਆਮ ਤੌਰ 'ਤੇ, ਉਪਰੋਕਤ ਤਰੀਕਿਆਂ ਵਿੱਚੋਂ ਜੋ ਵੀ ਤੁਸੀਂ ਚੁਣਦੇ ਹੋ, ਦੋ-ਅਯਾਮੀ ਖੋਜ ਦਾ ਨਤੀਜਾ ਇੱਕੋ ਜਿਹਾ ਹੋਵੇਗਾ:
ਇੱਕ ਫਾਰਮੂਲੇ ਵਿੱਚ ਕਈ VLOOKUPs ਦੀ ਵਰਤੋਂ ਕਰਨਾ
ਅਜਿਹਾ ਹੁੰਦਾ ਹੈ ਕਿ ਮੁੱਖ ਸਾਰਣੀ ਅਤੇ ਖੋਜ ਸਾਰਣੀ ਵਿੱਚ ਇੱਕ ਵੀ ਕਾਲਮ ਸਾਂਝਾ ਨਹੀਂ ਹੁੰਦਾ ਹੈ, ਅਤੇ ਇਹ ਤੁਹਾਨੂੰ ਆਮ ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰਨ ਤੋਂ ਰੋਕਦਾ ਹੈ ਵੀਪੀਆਰ. ਹਾਲਾਂਕਿ, ਇੱਕ ਹੋਰ ਸਾਰਣੀ ਹੈ ਜਿਸ ਵਿੱਚ ਉਹ ਜਾਣਕਾਰੀ ਨਹੀਂ ਹੈ ਜਿਸ ਵਿੱਚ ਸਾਡੀ ਦਿਲਚਸਪੀ ਹੈ, ਪਰ ਮੁੱਖ ਸਾਰਣੀ ਅਤੇ ਖੋਜ ਸਾਰਣੀ ਦੇ ਨਾਲ ਇੱਕ ਸਾਂਝਾ ਕਾਲਮ ਹੈ।
ਆਓ ਹੇਠਾਂ ਦਿੱਤੀ ਉਦਾਹਰਣ 'ਤੇ ਇੱਕ ਨਜ਼ਰ ਮਾਰੀਏ। ਸਾਡੇ ਕੋਲ ਇੱਕ ਕਾਲਮ ਦੇ ਨਾਲ ਇੱਕ ਮੇਨ ਟੇਬਲ ਹੈ SKU (ਨਵਾਂ), ਜਿੱਥੇ ਤੁਸੀਂ ਕਿਸੇ ਹੋਰ ਸਾਰਣੀ ਤੋਂ ਸੰਬੰਧਿਤ ਕੀਮਤਾਂ ਦੇ ਨਾਲ ਇੱਕ ਕਾਲਮ ਜੋੜਨਾ ਚਾਹੁੰਦੇ ਹੋ। ਇਸ ਤੋਂ ਇਲਾਵਾ, ਸਾਡੇ ਕੋਲ 2 ਲੁੱਕਅੱਪ ਟੇਬਲ ਹਨ। ਪਹਿਲੀ (ਲੁੱਕਅਪ ਟੇਬਲ 1) ਵਿੱਚ ਅੱਪਡੇਟ ਕੀਤੇ ਨੰਬਰ ਸ਼ਾਮਲ ਹਨ SKU (ਨਵਾਂ) ਅਤੇ ਉਤਪਾਦ ਦੇ ਨਾਮ, ਅਤੇ ਦੂਜਾ (ਲੁੱਕਅੱਪ ਟੇਬਲ 2) - ਉਤਪਾਦ ਦੇ ਨਾਮ ਅਤੇ ਪੁਰਾਣੇ ਨੰਬਰ SKU (ਪੁਰਾਣਾ).
ਦੂਜੀ ਲੁੱਕਅਪ ਟੇਬਲ ਤੋਂ ਮੁੱਖ ਸਾਰਣੀ ਵਿੱਚ ਕੀਮਤਾਂ ਜੋੜਨ ਲਈ, ਤੁਹਾਨੂੰ ਇੱਕ ਕਾਰਵਾਈ ਕਰਨੀ ਚਾਹੀਦੀ ਹੈ ਜਿਸਨੂੰ ਡਬਲ ਕਿਹਾ ਜਾਂਦਾ ਹੈ ਵੀਪੀਆਰ ਜਾਂ ਨੇਸਟਡ ਵੀਪੀਆਰ.
- ਇੱਕ ਫੰਕਸ਼ਨ ਲਿਖੋ ਵੀਪੀਆਰ, ਜੋ ਸਾਰਣੀ ਵਿੱਚ ਉਤਪਾਦ ਦਾ ਨਾਮ ਲੱਭਦਾ ਹੈ ਖੋਜ ਸਾਰਣੀ 1ਵਰਤ SKU, ਲੋੜੀਦੇ ਮੁੱਲ ਦੇ ਰੂਪ ਵਿੱਚ:
=VLOOKUP(A2,New_SKU,2,FALSE)
=ВПР(A2;New_SKU;2;ЛОЖЬ)
ਇੱਥੇ ਨਵਾਂ_SKU - ਨਾਮੀ ਰੇਂਜ $A:$B ਸਾਰਣੀ ਵਿੱਚ ਖੋਜ ਸਾਰਣੀ 1, 2 - ਇਹ ਕਾਲਮ B ਹੈ, ਜਿਸ ਵਿੱਚ ਵਸਤੂਆਂ ਦੇ ਨਾਮ ਹਨ (ਉਪਰੋਕਤ ਤਸਵੀਰ ਵੇਖੋ)
- ਇੱਕ ਸਾਰਣੀ ਤੋਂ ਕੀਮਤਾਂ ਪਾਉਣ ਲਈ ਇੱਕ ਫਾਰਮੂਲਾ ਲਿਖੋ ਖੋਜ ਸਾਰਣੀ 2 ਜਾਣੇ-ਪਛਾਣੇ ਉਤਪਾਦ ਦੇ ਨਾਮ 'ਤੇ ਆਧਾਰਿਤ. ਅਜਿਹਾ ਕਰਨ ਲਈ, ਨਵੇਂ ਫੰਕਸ਼ਨ ਲਈ ਲੁੱਕਅਪ ਮੁੱਲ ਦੇ ਤੌਰ 'ਤੇ ਤੁਹਾਡੇ ਦੁਆਰਾ ਪਹਿਲਾਂ ਬਣਾਏ ਗਏ ਫਾਰਮੂਲੇ ਨੂੰ ਪੇਸਟ ਕਰੋ ਵੀਪੀਆਰ:
=VLOOKUP(VLOOKUP(A2,New_SKU,2,FALSE),Price,3,FALSE)
=ВПР(ВПР(A2;New_SKU;2;ЛОЖЬ);Price;3;ЛОЖЬ)
ਇੱਥੇ ਕੀਮਤ - ਨਾਮੀ ਰੇਂਜ $A:$C ਸਾਰਣੀ ਵਿੱਚ ਖੋਜ ਸਾਰਣੀ 2, 3 ਕਾਲਮ C ਹੈ ਜਿਸ ਵਿੱਚ ਕੀਮਤਾਂ ਹਨ।
ਹੇਠਾਂ ਦਿੱਤੀ ਤਸਵੀਰ ਸਾਡੇ ਦੁਆਰਾ ਬਣਾਏ ਗਏ ਫਾਰਮੂਲੇ ਦੁਆਰਾ ਵਾਪਸ ਕੀਤੇ ਗਏ ਨਤੀਜੇ ਨੂੰ ਦਰਸਾਉਂਦੀ ਹੈ:
VLOOKUP ਅਤੇ INDIRECT ਦੀ ਵਰਤੋਂ ਕਰਦੇ ਹੋਏ ਵੱਖ-ਵੱਖ ਟੇਬਲਾਂ ਤੋਂ ਡੇਟਾ ਦਾ ਗਤੀਸ਼ੀਲ ਬਦਲ
ਪਹਿਲਾਂ, ਆਓ ਸਪੱਸ਼ਟ ਕਰੀਏ ਕਿ ਅਸੀਂ ਇੱਕ ਦੂਜੇ ਨੂੰ ਸਹੀ ਤਰ੍ਹਾਂ ਸਮਝਦੇ ਹਾਂ ਇਹ ਯਕੀਨੀ ਬਣਾਉਣ ਲਈ "ਵੱਖ-ਵੱਖ ਟੇਬਲਾਂ ਤੋਂ ਡੇਟਾ ਦਾ ਗਤੀਸ਼ੀਲ ਬਦਲ" ਸਮੀਕਰਨ ਦੁਆਰਾ ਸਾਡਾ ਕੀ ਮਤਲਬ ਹੈ।
ਅਜਿਹੀਆਂ ਸਥਿਤੀਆਂ ਹੁੰਦੀਆਂ ਹਨ ਜਦੋਂ ਇੱਕੋ ਫਾਰਮੈਟ ਦੇ ਡੇਟਾ ਵਾਲੀਆਂ ਕਈ ਸ਼ੀਟਾਂ ਹੁੰਦੀਆਂ ਹਨ, ਅਤੇ ਕਿਸੇ ਖਾਸ ਸ਼ੀਟ ਤੋਂ ਲੋੜੀਂਦੀ ਜਾਣਕਾਰੀ ਨੂੰ ਐਕਸਟਰੈਕਟ ਕਰਨਾ ਜ਼ਰੂਰੀ ਹੁੰਦਾ ਹੈ, ਜੋ ਕਿ ਦਿੱਤੇ ਗਏ ਸੈੱਲ ਵਿੱਚ ਦਰਜ ਕੀਤੇ ਗਏ ਮੁੱਲ ਦੇ ਅਧਾਰ ਤੇ ਹੁੰਦਾ ਹੈ। ਮੈਨੂੰ ਲੱਗਦਾ ਹੈ ਕਿ ਇੱਕ ਉਦਾਹਰਣ ਨਾਲ ਇਸ ਨੂੰ ਸਮਝਾਉਣਾ ਸੌਖਾ ਹੈ।
ਕਲਪਨਾ ਕਰੋ ਕਿ ਤੁਹਾਡੇ ਕੋਲ ਇੱਕੋ ਉਤਪਾਦਾਂ ਅਤੇ ਇੱਕੋ ਫਾਰਮੈਟ ਵਿੱਚ ਕਈ ਖੇਤਰਾਂ ਲਈ ਵਿਕਰੀ ਰਿਪੋਰਟਾਂ ਹਨ। ਤੁਸੀਂ ਕਿਸੇ ਖਾਸ ਖੇਤਰ ਲਈ ਵਿਕਰੀ ਦੇ ਅੰਕੜੇ ਲੱਭਣਾ ਚਾਹੁੰਦੇ ਹੋ:
ਜੇ ਤੁਹਾਡੇ ਕੋਲ ਸਿਰਫ ਦੋ ਅਜਿਹੀਆਂ ਰਿਪੋਰਟਾਂ ਹਨ, ਤਾਂ ਤੁਸੀਂ ਫੰਕਸ਼ਨਾਂ ਦੇ ਨਾਲ ਇੱਕ ਅਪਮਾਨਜਨਕ ਸਧਾਰਨ ਫਾਰਮੂਲਾ ਵਰਤ ਸਕਦੇ ਹੋ ਵੀਪੀਆਰ и IF (IF) ਖੋਜ ਕਰਨ ਲਈ ਲੋੜੀਂਦੀ ਰਿਪੋਰਟ ਦੀ ਚੋਣ ਕਰਨ ਲਈ:
=VLOOKUP($D$2,IF($D3="FL",FL_Sales,CA_Sales),2,FALSE)
=ВПР($D$2;ЕСЛИ($D3="FL";FL_Sales;CA_Sales);2;ЛОЖЬ)
ਕਿੱਥੇ:
- $ ਡੀ $ 2 ਇੱਕ ਸੈੱਲ ਹੈ ਜਿਸ ਵਿੱਚ ਉਤਪਾਦ ਦਾ ਨਾਮ ਹੁੰਦਾ ਹੈ। ਨੋਟ ਕਰੋ ਕਿ ਅਸੀਂ ਦੂਜੇ ਸੈੱਲਾਂ ਵਿੱਚ ਫਾਰਮੂਲੇ ਦੀ ਨਕਲ ਕਰਦੇ ਸਮੇਂ ਲੁੱਕਅਪ ਮੁੱਲ ਨੂੰ ਬਦਲਣ ਤੋਂ ਬਚਣ ਲਈ ਇੱਥੇ ਸੰਪੂਰਨ ਸੰਦਰਭਾਂ ਦੀ ਵਰਤੋਂ ਕਰਦੇ ਹਾਂ।
- $D3 ਖੇਤਰ ਦੇ ਨਾਮ ਨਾਲ ਇੱਕ ਸੈੱਲ ਹੈ। ਅਸੀਂ ਇੱਕ ਪੂਰਨ ਕਾਲਮ ਸੰਦਰਭ ਅਤੇ ਇੱਕ ਸੰਬੰਧਿਤ ਕਤਾਰ ਸੰਦਰਭ ਦੀ ਵਰਤੋਂ ਕਰ ਰਹੇ ਹਾਂ ਕਿਉਂਕਿ ਅਸੀਂ ਉਸੇ ਕਾਲਮ ਵਿੱਚ ਦੂਜੇ ਸੈੱਲਾਂ ਵਿੱਚ ਫਾਰਮੂਲੇ ਦੀ ਨਕਲ ਕਰਨ ਦੀ ਯੋਜਨਾ ਬਣਾ ਰਹੇ ਹਾਂ।
- FL_ਸਾਲes и CA_ਵਿਕਰੀ - ਉਹਨਾਂ ਟੇਬਲਾਂ (ਜਾਂ ਨਾਮੀ ਰੇਂਜਾਂ) ਦੇ ਨਾਮ ਜਿਹਨਾਂ ਵਿੱਚ ਸੰਬੰਧਿਤ ਵਿਕਰੀ ਰਿਪੋਰਟਾਂ ਹੁੰਦੀਆਂ ਹਨ। ਤੁਸੀਂ, ਬੇਸ਼ਕ, ਉਦਾਹਰਨ ਲਈ, ਆਮ ਸ਼ੀਟ ਨਾਮ ਅਤੇ ਸੈੱਲ ਰੇਂਜ ਦੇ ਹਵਾਲੇ ਵਰਤ ਸਕਦੇ ਹੋ 'FL ਸ਼ੀਟ'!$A$3:$B$10, ਪਰ ਨਾਮਿਤ ਰੇਂਜ ਬਹੁਤ ਜ਼ਿਆਦਾ ਸੁਵਿਧਾਜਨਕ ਹਨ।
ਹਾਲਾਂਕਿ, ਜਦੋਂ ਬਹੁਤ ਸਾਰੇ ਅਜਿਹੇ ਟੇਬਲ ਹੁੰਦੇ ਹਨ, ਫੰਕਸ਼ਨ IF ਸਭ ਤੋਂ ਵਧੀਆ ਹੱਲ ਨਹੀਂ ਹੈ। ਇਸ ਦੀ ਬਜਾਏ, ਤੁਸੀਂ ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰ ਸਕਦੇ ਹੋ ਅਸਿੱਧੇ (ਅਪ੍ਰਤੱਖ) ਲੋੜੀਂਦੀ ਖੋਜ ਰੇਂਜ ਵਾਪਸ ਕਰਨ ਲਈ।
ਜਿਵੇਂ ਕਿ ਤੁਸੀਂ ਸ਼ਾਇਦ ਜਾਣਦੇ ਹੋ, ਫੰਕਸ਼ਨ ਅਸਿੱਧੇ ਇੱਕ ਟੈਕਸਟ ਸਤਰ ਦੁਆਰਾ ਦਿੱਤੇ ਗਏ ਲਿੰਕ ਨੂੰ ਵਾਪਸ ਕਰਨ ਲਈ ਵਰਤਿਆ ਜਾਂਦਾ ਹੈ, ਜਿਸਦੀ ਸਾਨੂੰ ਹੁਣ ਲੋੜ ਹੈ। ਇਸ ਲਈ, ਦਲੇਰੀ ਨਾਲ ਉਪਰੋਕਤ ਫਾਰਮੂਲੇ ਵਿੱਚ ਸਮੀਕਰਨ ਨੂੰ ਫੰਕਸ਼ਨ ਨਾਲ ਬਦਲੋ IF ਫੰਕਸ਼ਨ ਨਾਲ ਲਿੰਕ ਕਰਨ ਲਈ ਅਸਿੱਧੇ. ਇੱਥੇ ਇੱਕ ਸੁਮੇਲ ਹੈ ਵੀਪੀਆਰ и ਅਸਿੱਧੇ ਨਾਲ ਵਧੀਆ ਕੰਮ ਕਰਦਾ ਹੈ:
=VLOOKUP($D$2,INDIRECT($D3&"_Sales"),2,FALSE)
=ВПР($D$2;ДВССЫЛ($D3&"_Sales");2;ЛОЖЬ)
ਕਿੱਥੇ:
- $ ਡੀ $ 2 - ਇਹ ਉਤਪਾਦ ਦੇ ਨਾਮ ਵਾਲਾ ਇੱਕ ਸੈੱਲ ਹੈ, ਇਹ ਪੂਰਨ ਲਿੰਕ ਦੇ ਕਾਰਨ ਬਦਲਿਆ ਨਹੀਂ ਹੈ।
- $D3 ਖੇਤਰ ਦੇ ਨਾਮ ਦੇ ਪਹਿਲੇ ਹਿੱਸੇ ਵਾਲਾ ਸੈੱਲ ਹੈ। ਸਾਡੀ ਉਦਾਹਰਨ ਵਿੱਚ, ਇਹ FL.
- _ਵਿਕਰੀ - ਸਾਰੀਆਂ ਨਾਮਿਤ ਰੇਂਜਾਂ ਜਾਂ ਟੇਬਲਾਂ ਦੇ ਨਾਮ ਦਾ ਸਾਂਝਾ ਹਿੱਸਾ। ਜਦੋਂ ਸੈੱਲ D3 ਵਿੱਚ ਮੁੱਲ ਨਾਲ ਜੋੜਿਆ ਜਾਂਦਾ ਹੈ, ਤਾਂ ਇਹ ਲੋੜੀਂਦੀ ਰੇਂਜ ਦਾ ਪੂਰੀ ਤਰ੍ਹਾਂ ਯੋਗ ਨਾਮ ਬਣਾਉਂਦਾ ਹੈ। ਹੇਠਾਂ ਉਹਨਾਂ ਲਈ ਕੁਝ ਵੇਰਵੇ ਹਨ ਜੋ ਫੰਕਸ਼ਨ ਲਈ ਨਵੇਂ ਹਨ ਅਸਿੱਧੇ.
INDIRECT ਅਤੇ VLOOKUP ਕਿਵੇਂ ਕੰਮ ਕਰਦੇ ਹਨ
ਪਹਿਲਾਂ, ਮੈਂ ਤੁਹਾਨੂੰ ਫੰਕਸ਼ਨ ਦਾ ਸੰਟੈਕਸ ਯਾਦ ਦਿਵਾਉਣਾ ਚਾਹੁੰਦਾ ਹਾਂ ਅਸਿੱਧੇ (ਅਸਿੱਧੇ):
INDIRECT(ref_text,[a1])
ДВССЫЛ(ссылка_на_текст;[a1])
ਪਹਿਲਾ ਆਰਗੂਮੈਂਟ ਇੱਕ ਸੈੱਲ ਸੰਦਰਭ (A1 ਜਾਂ R1C1 ਸ਼ੈਲੀ), ਇੱਕ ਰੇਂਜ ਨਾਮ, ਜਾਂ ਇੱਕ ਟੈਕਸਟ ਸਤਰ ਹੋ ਸਕਦਾ ਹੈ। ਦੂਜੀ ਦਲੀਲ ਇਹ ਨਿਰਧਾਰਤ ਕਰਦੀ ਹੈ ਕਿ ਪਹਿਲੀ ਆਰਗੂਮੈਂਟ ਵਿੱਚ ਲਿੰਕ ਦੀ ਕਿਹੜੀ ਸ਼ੈਲੀ ਸ਼ਾਮਲ ਹੈ:
- A1ਜੇਕਰ ਦਲੀਲ ਹੈ ਸੱਚਾ ਕੋਡ (ਸਹੀ) ਜਾਂ ਨਿਰਦਿਸ਼ਟ ਨਹੀਂ;
- ਆਰ 1 ਸੀ 1, ਜੇ Fਏਐਸ ਈ (ਗਲਤ)।
ਸਾਡੇ ਕੇਸ ਵਿੱਚ, ਲਿੰਕ ਦੀ ਸ਼ੈਲੀ ਹੈ A1, ਇਸ ਲਈ ਤੁਸੀਂ ਦੂਜੀ ਦਲੀਲ ਨੂੰ ਛੱਡ ਸਕਦੇ ਹੋ ਅਤੇ ਪਹਿਲੇ 'ਤੇ ਧਿਆਨ ਕੇਂਦਰਿਤ ਕਰ ਸਕਦੇ ਹੋ।
ਇਸ ਲਈ ਆਓ ਸਾਡੀ ਵਿਕਰੀ ਰਿਪੋਰਟਾਂ 'ਤੇ ਵਾਪਸ ਆਓ। ਜੇ ਤੁਹਾਨੂੰ ਯਾਦ ਹੈ, ਤਾਂ ਹਰੇਕ ਰਿਪੋਰਟ ਇੱਕ ਵੱਖਰੀ ਸ਼ੀਟ 'ਤੇ ਸਥਿਤ ਇੱਕ ਵੱਖਰੀ ਸਾਰਣੀ ਹੈ। ਫਾਰਮੂਲੇ ਦੇ ਸਹੀ ਢੰਗ ਨਾਲ ਕੰਮ ਕਰਨ ਲਈ, ਤੁਹਾਨੂੰ ਆਪਣੀਆਂ ਟੇਬਲਾਂ (ਜਾਂ ਰੇਂਜਾਂ) ਨੂੰ ਨਾਮ ਦੇਣਾ ਚਾਹੀਦਾ ਹੈ, ਅਤੇ ਸਾਰੇ ਨਾਵਾਂ ਦਾ ਸਾਂਝਾ ਹਿੱਸਾ ਹੋਣਾ ਚਾਹੀਦਾ ਹੈ। ਉਦਾਹਰਨ ਲਈ, ਇਸ ਤਰ੍ਹਾਂ: CA_ਵਿਕਰੀ, FL_Sales, TX_ਵਿਕਰੀ ਇਤਆਦਿ. ਜਿਵੇਂ ਕਿ ਤੁਸੀਂ ਦੇਖ ਸਕਦੇ ਹੋ, “_Sales” ਸਾਰੇ ਨਾਵਾਂ ਵਿੱਚ ਮੌਜੂਦ ਹੈ।
ਫੰਕਸ਼ਨ ਅਸਿੱਧੇ ਕਾਲਮ D ਵਿੱਚ ਮੁੱਲ ਅਤੇ ਟੈਕਸਟ ਸਤਰ “_Sales” ਨੂੰ ਜੋੜਦਾ ਹੈ, ਇਸ ਤਰ੍ਹਾਂ ਦੱਸਦਾ ਹੈ ਵੀਪੀਆਰ ਜਿਸ ਸਾਰਣੀ ਵਿੱਚ ਖੋਜ ਕਰਨੀ ਹੈ। ਜੇਕਰ ਸੈੱਲ D3 ਵਿੱਚ ਮੁੱਲ "FL" ਹੈ, ਤਾਂ ਫਾਰਮੂਲਾ ਸਾਰਣੀ ਦੀ ਖੋਜ ਕਰੇਗਾ FL_Sales, ਜੇਕਰ "CA" - ਸਾਰਣੀ ਵਿੱਚ CA_ਵਿਕਰੀ ਇਤਆਦਿ.
ਫੰਕਸ਼ਨਾਂ ਦਾ ਨਤੀਜਾ ਵੀਪੀਆਰ и ਅਸਿੱਧੇ ਹੇਠ ਲਿਖੇ ਹੋਣਗੇ:
ਜੇਕਰ ਡੇਟਾ ਵੱਖ-ਵੱਖ ਐਕਸਲ ਕਿਤਾਬਾਂ ਵਿੱਚ ਸਥਿਤ ਹੈ, ਤਾਂ ਤੁਹਾਨੂੰ ਨਾਮਿਤ ਰੇਂਜ ਤੋਂ ਪਹਿਲਾਂ ਕਿਤਾਬ ਦਾ ਨਾਮ ਜੋੜਨ ਦੀ ਲੋੜ ਹੈ, ਉਦਾਹਰਨ ਲਈ:
=VLOOKUP($D$2,INDIRECT($D3&"Workbook1!_Sales"),2,FALSE)
=ВПР($D$2;ДВССЫЛ($D3&"Workbook1!_Sales");2;ЛОЖЬ)
ਜੇਕਰ ਫੰਕਸ਼ਨ ਅਸਿੱਧੇ ਕਿਸੇ ਹੋਰ ਵਰਕਬੁੱਕ ਦਾ ਹਵਾਲਾ ਦਿੰਦਾ ਹੈ, ਉਹ ਵਰਕਬੁੱਕ ਖੁੱਲੀ ਹੋਣੀ ਚਾਹੀਦੀ ਹੈ। ਜੇਕਰ ਇਹ ਬੰਦ ਹੈ, ਤਾਂ ਫੰਕਸ਼ਨ ਇੱਕ ਗਲਤੀ ਦੀ ਰਿਪੋਰਟ ਕਰੇਗਾ। #REF! (#SSYL!)